File Coverage

blib/lib/Test2/Plugin/DBIProfile.pm

Criterion	Covered	Total	%
statement	31	32	96.8
branch	3	6	50.0
condition	1	2	50.0
subroutine	7	7	100.0
pod	0	1	0.0
total	42	48	87.5

package Test2::Plugin::DBIProfile;
use strict;
use warnings;

our $VERSION = '0.002003';

use DBI::Profile qw/dbi_profile_merge_nodes/;
use Test2::API qw/test2_add_callback_exit/;
use Test2::Util::Times qw/render_duration/;

my $ADDED_HOOK = 0;

sub import {
    my $class = shift;
    my ($path) = @_;

    if (defined $path) {
        $ENV{DBI_PROFILE} = $path;
    }
    else {
        $ENV{DBI_PROFILE} //= "!MethodClass";
    }

    return if $ADDED_HOOK++;

    $DBI::Profile::ON_DESTROY_DUMP = undef;
    $DBI::Profile::ON_FLUSH_DUMP   = undef;

    test2_add_callback_exit(\&send_profile_event);
}

sub send_profile_event {
    my ($ctx, $real, $new) = @_;

    my $p = $DBI::shared_profile or return;

    my $data = $p->{Data};
    my ($summary) = $p->format;

    my @totals;
    dbi_profile_merge_nodes(\@totals, $data);
    my ($count, $time) = @totals;

    $ctx->send_ev2(
        dbi_profile => $data,

        about => {package => __PACKAGE__, details => $summary},
        info  => [{tag => 'DBI-PROF', details => $summary}],

        harness_job_fields => [
            {name => "dbi_time",  details => render_duration($time), raw => $time},
            {name => "dbi_calls", details => $count},
        ],
    );
}

1;

__END__