File Coverage

blib/lib/Test2/IPC.pm

Criterion	Covered	Total	%
statement	22	49	44.9
branch	1	18	5.5
condition	0	6	0.0
subroutine	8	11	72.7
pod	1	2	50.0
total	32	86	37.2

package Test2::IPC;
use strict;
use warnings;

our $VERSION = '0.000044';

use Test2::API::Instance;
use Test2::Util qw/get_tid/;
use Test2::API qw{
    test2_init_done
    test2_ipc
    test2_ipc_enable_polling
    test2_pid
    test2_stack
    test2_tid
};

use Carp qw/confess/;

our @EXPORT_OK = qw/cull/;
use base 'Exporter';

sub import {
    goto &Exporter::import unless test2_init_done();

    confess "Cannot add IPC in a child process" if test2_pid() != $$;
    confess "Cannot add IPC in a child thread"  if test2_tid() != get_tid();

    Test2::API::_set_ipc(_make_ipc());
    apply_ipc(test2_stack());

    goto &Exporter::import;
}

sub _make_ipc {
    # Find a driver
    my ($driver) = Test2::API::test2_ipc_drivers();
    unless ($driver) {
        require Test2::IPC::Driver::Files;
        $driver = 'Test2::IPC::Driver::Files';
    }

    return $driver->new();
}

sub apply_ipc {
    my $stack = shift;

    my ($root) = @$stack;

    return unless $root;

    confess "Cannot add IPC in a child process" if $root->pid != $$;
    confess "Cannot add IPC in a child thread"  if $root->tid != get_tid();

    my $ipc = $root->ipc || test2_ipc() || _make_ipc();

    # Add the IPC to all hubs
    for my $hub (@$stack) {
        my $has = $hub->ipc;
        confess "IPC Mismatch!" if $has && $has != $ipc;
        next if $has;
        $hub->set_ipc($ipc);
        $ipc->add_hub($hub->hid);
    }

    test2_ipc_enable_polling();

    return $ipc;
}

sub cull {
    my $ctx = context();
    $ctx->hub->cull;
    $ctx->release;
}

1;

__END__