File Coverage

blib/lib/Test2/Event/Ok.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch	12	12	100.0
condition	7	8	87.5
subroutine	10	10	100.0
pod	3	4	75.0
total	66	68	97.0

package Test2::Event::Ok;
use strict;
use warnings;

our $VERSION = '0.000043';
$VERSION = eval $VERSION;    ## no critic (BuiltinFunctions::ProhibitStringyEval)

use base 'Test2::Event';
use Test2::Util::HashBase qw{
    pass effective_pass name todo
};

sub init {
    my $self = shift;

    # Do not store objects here, only true or false
    $self->{+PASS} = $self->{+PASS} ? 1 : 0;
    $self->{+EFFECTIVE_PASS} = $self->{+PASS} || (defined($self->{+TODO}) ? 1 : 0);

    my $name = $self->{+NAME} or return;
    return unless index($name, '#') != -1 || index($name, "\n") != -1;
    $self->trace->throw("'$name' is not a valid name, names must not contain '#' or newlines.")
}

{
    no warnings 'redefine';
    sub set_todo {
        my $self = shift;
        my ($todo) = @_;
        $self->{+TODO} = $todo;
        $self->{+EFFECTIVE_PASS} = defined($todo) ? 1 : $self->{+PASS};
    }
}

sub increments_count { 1 };

sub causes_fail { !$_[0]->{+EFFECTIVE_PASS} }

sub summary {
    my $self = shift;

    my $name = $self->{+NAME} || "Nameless Assertion";

    my $todo = $self->{+TODO};
    if ($todo) {
        $name .= " (TODO: $todo)";
    }
    elsif (defined $todo) {
        $name .= " (TODO)"
    }

    return $name;
}

1;

__END__