File Coverage

blib/lib/Test/Stream/Plugin/Intercept.pm

Criterion	Covered	Total	%
statement	49	49	100.0
branch	6	6	100.0
condition	10	12	83.3
subroutine	12	12	100.0
pod	1	1	100.0
total	78	80	97.5

package Test::Stream::Plugin::Intercept;
use strict;
use warnings;

use Scalar::Util qw/blessed/;

use Test::Stream::Util qw/try/;
use Test::Stream::Context qw/context/;

use Test::Stream::Hub::Interceptor();
use Test::Stream::Hub::Interceptor::Terminator();

use Test::Stream::Exporter qw/import default_exports/;
default_exports qw/intercept/;
no Test::Stream::Exporter;

sub intercept(&) {
    my $code = shift;

    my $ctx = context();

    my $ipc;
    if ($INC{'Test/Stream/IPC.pm'}) {
        my ($driver) = Test::Stream::IPC->drivers;
        $ipc = $driver->new;
    }

    my $hub = Test::Stream::Hub::Interceptor->new(
        ipc => $ipc,
        no_ending => 1,
    );

    my @events;
    $hub->listen(sub { push @events => $_[1] });

    $ctx->stack->top; # Make sure there is a top hub before we begin.
    $ctx->stack->push($hub);
    my ($ok, $err) = try {
        local $ENV{TS_TERM_SIZE} = 80;
        $code->(
            hub => $hub,
            context => $ctx->snapshot,
        );
    };
    $hub->cull;
    $ctx->stack->pop($hub);

    my $dbg = $ctx->debug;
    $ctx->release;

    die $err unless $ok
        || (blessed($err) && $err->isa('Test::Stream::Hub::Interceptor::Terminator'));

    $hub->finalize($dbg, 1)
        if $ok
        && !$hub->no_ending
        && !$hub->state->ended;

    return \@events;
}

1;

__END__