File Coverage

blib/lib/Test/Stream/Workflow/Meta.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	12	14	85.7
condition	4	8	50.0
subroutine	12	12	100.0
pod	4	5	80.0
total	80	87	91.9

package Test::Stream::Workflow::Meta;
use strict;
use warnings;

use Carp qw/confess croak/;
use Scalar::Util qw/blessed/;

use Test::Stream::Workflow::Unit;

use Test::Stream::HashBase(
    accessors => [qw/unit runner runner_args autorun/],
);

my %METAS;

sub init {
    my $self = shift;

    confess "unit is a required attribute"
        unless $self->{+UNIT};
}

sub build {
    my $class = shift;
    my ($pkg, $file, $start_line, $end_line) = @_;

    return $METAS{$pkg} if $METAS{$pkg};

    my $unit = Test::Stream::Workflow::Unit->new(
        name       => $pkg,
        package    => $pkg,
        file       => $file,
        start_line => $start_line,
        end_line   => $end_line,
        type       => 'group',
        is_root    => 1,
    );

    my $meta = $class->new(
        UNIT()    => $unit,
        AUTORUN() => 1,
    );

    $METAS{$pkg} = $meta;

    my $hub = Test::Stream::Sync->stack->top;
    $hub->follow_up(
        sub {
            return unless $METAS{$pkg};
            return unless $METAS{$pkg}->autorun;
            $METAS{$pkg}->run;
            # Make sure the build cannot be found after done_testing
            delete $METAS{$pkg}->{+UNIT};
        }
    );

    return $meta;
}

sub purge {
    my $it = shift;
    my $pkg = $_[0];

    $pkg ||= $it->{+UNIT}->package if blessed($it) && $it->{+UNIT};

    croak "You must specify a package to purge"
        unless $pkg;

    delete $METAS{$pkg};
}

sub get {
    my $class = shift;
    my ($pkg) = @_;
    return $METAS{$pkg};
}

sub run {
    my $self = shift;
    my $runner = $self->runner;
    unless ($runner) {
        require Test::Stream::Workflow::Runner;
        $runner = 'Test::Stream::Workflow::Runner';
    }

    $self->unit->do_post;

    $runner->run(
        unit => $self->unit,
        args => $self->runner_args || [],
        no_final => 1
    );
}

1;

__END__