File Coverage

blib/lib/Test/Stream/Compare/Set.pm

Criterion	Covered	Total	%
statement	64	65	98.4
branch	19	20	95.0
condition	12	13	92.3
subroutine	15	15	100.0
pod	4	8	50.0
total	114	121	94.2

package Test::Stream::Compare::Set;
use strict;
use warnings;

use Test::Stream::Compare;
use Test::Stream::HashBase(
    base => 'Test::Stream::Compare',
    accessors => [qw/checks _reduction/],
);

use Test::Stream::Delta;

use Carp qw/croak confess/;
use Scalar::Util qw/reftype/;

sub init {
    my $self = shift;

    my $reduction = delete $self->{reduction} || 'any';

    $self->{+CHECKS} ||= [];

    $self->set_reduction($reduction);

    $self->SUPER::init();
}

sub name      { '' }
sub operator  { $_[0]->{+_REDUCTION} }
sub reduction { $_[0]->{+_REDUCTION} }

my %VALID = (any => 1, all => 1, none => 1);
sub set_reduction {
    my $self = shift;
    my ($redu) = @_;

    croak "'$redu' is not a valid set reduction"
        unless $VALID{$redu};

    $self->{+_REDUCTION} = $redu;
}

sub verify {
    my $self = shift;
    my %params = @_;
    return $params{exists} ? 1 : 0;
}

sub add_check {
    my $self = shift;
    push @{$self->{+CHECKS}} => @_;
}

sub deltas {
    my $self = shift;
    my %params = @_;

    my $checks    = $self->{+CHECKS};
    my $reduction = $self->{+_REDUCTION};
    my $convert   = $params{convert};

    unless ($checks && @$checks) {
        my $file = $self->file;
        my $lines = $self->lines;

        my $extra = "";
        if ($file and $lines and @$lines) {
            my $lns = (@$lines > 1 ? 'lines ' : 'line ' ) .  join ', ', @$lines;
            $extra = " (Set defined in $file $lns)";
        }

        die "No checks defined for set$extra\n";
    }

    my @deltas;
    my $i = 0;
    for my $check (@$checks) {
        my $c = $convert->($check);
        my $id = [META => "Check " . $i++];
        my @d = $c->run(%params, id => $id);

        if ($reduction eq 'any') {
            return () unless @d;
            push @deltas => @d;
        }
        elsif ($reduction eq 'all') {
            push @deltas => @d;
        }
        elsif ($reduction eq 'none') {
            push @deltas => Test::Stream::Delta->new(
                verified => 0,
                id       => $id,
                got      => $params{got},
                check    => $c,
            ) unless @d;
        }
        else {
            die "Invalid reduction: $reduction\n";
        }
    }

    return @deltas;
}

1;

__END__