File Coverage

blib/lib/Test/SetupTeardown.pm

Criterion	Covered	Total	%
statement	35	39	89.7
branch	12	12	100.0
condition	3	3	100.0
subroutine	11	13	84.6
pod	2	3	66.6
total	63	70	90.0

package Test::SetupTeardown;

use strict;
use warnings;

use Test::Builder;
use Try::Tiny;

our $VERSION = 0.004;

sub new {
    my ($class, %routines) = @_;
    my $self = \%routines;
    bless $self, $class;
    $self->{begin}->() if $self->{begin};
    return $self;
}

# interrupting e.g. prove with C-c bypasses the DESTROY method, so
# trap SIGINT.  just die()-ing does not seem to work -- I just get
# bin/perl t/whatever.t.  exit(1) seems to work better.  in any case I
# don't see any output anywhere so *shrug*

sub handler {
    my $sig = shift;
    print "Test::SetupTeardown caught signal $sig, aborting\n";
    exit 1;
}

use sigtrap handler => \&handler, qw/normal-signals untrapped/;

sub run_test {
    my ($self, $description, $coderef) = @_;
    my $exception_while_running_block;

    if ($ENV{TEST_ST_ONLY}
        and $ENV{TEST_ST_ONLY} ne $description) {
        # TEST_ST_ONLY is set for another test case
        return;
    }

    Test::Builder->new->note($description);

    # Run setup() routine before each test
    $self->{setup}->() if $self->{setup};

    try {
        # Catch all exceptions thrown by the block, to be rethrown
        # later after the teardown has had a chance to run
        $coderef->();
    } catch {
        # Stash this for now
        $exception_while_running_block = $_;
    };

    # Run teardown routine after each test
    $self->{teardown}->() if $self->{teardown};

    if ($exception_while_running_block) {
        # The teardown has run now, rethrow the exception
        die $exception_while_running_block;
    }
}

sub DESTROY {
    my $self = shift;
    try {
        $self->{end}->() if $self->{end};
    } catch {
        # an exception from end() won't bubble up from DESTROY,
        # so at least we should warn
        warn $_;
    };
}

1;
__END__