File Coverage

blib/lib/Test/Rsyslog.pm

Criterion	Covered	Total	%
statement	104	112	92.8
branch	21	40	52.5
condition	5	9	55.5
subroutine	20	20	100.0
pod	5	5	100.0
total	155	186	83.3

package Test::Rsyslog;

use 5.010;
use strict;
use warnings;
use File::Temp();
use Fcntl();
use File::Spec();
use FileHandle();
use English qw( -no_match_vars );
use Carp();
use POSIX();
use Config;

our $VERSION = '0.01';

sub _USER_READ_WRITE_PERMISSIONS         { return 600 }
sub _USER_READ_WRITE_EXECUTE_PERMISSIONS { return 700 }

sub socket_path {
    my ($self) = @_;
    return $self->{_socket_path};
}

sub find {
    my ( $self, $string ) = @_;
    my @found;
    my $handle = FileHandle->new( $self->{_messages_path}, Fcntl::O_RDONLY() );
    binmode $handle, ':encoding(UTF-8)';
    if ($handle) {
        $string =~ s/([\x00-\x1F])/'#' . sprintf '%03o', ord $1/smxeg;
        my $quoted = quotemeta $string;
        while ( my $line = <$handle> ) {
            chomp $line;
            if ( $line =~ /$quoted/smx ) {
                push @found, $line;
            }
        }
    }
    elsif ( $OS_ERROR == POSIX::ENOENT() ) {
    }
    else {
        Carp::croak(
            "Failed to open $self->{_messages_path} for reading:$OS_ERROR");
    }
    return @found;
}

sub new {
    my ($class) = @_;
    my $self = bless {}, $class;
    $self->{_root_directory} = File::Temp::mktemp(
        File::Spec->catfile(
            File::Spec->tmpdir(), 'perl_test_rsyslog_XXXXXXXXXXX'
        )
    );
    mkdir $self->{_root_directory}, oct _USER_READ_WRITE_EXECUTE_PERMISSIONS()
      or Carp::croak("Failed to mkdir $self->{_root_directory}:$OS_ERROR");
    $self->{_socket_path} =
      File::Spec->catfile( $self->{_root_directory}, 'rsyslog.sock' );
    $self->{_messages_path} =
      File::Spec->catfile( $self->{_root_directory}, 'messages' );
    $self->{_pid_path} = File::Spec->catfile( $self->{_root_directory}, 'pid' );
    $self->{_config_path} =
      File::Spec->catfile( $self->{_root_directory}, 'rsyslog.conf' );
    my $config_handle = FileHandle->new(
        $self->{_config_path},
        Fcntl::O_WRONLY() | Fcntl::O_CREAT() | Fcntl::O_EXCL(),
        oct _USER_READ_WRITE_PERMISSIONS()
      )
      or
      Carp::croak("Failed to open $self->{_config_path} for writing:$OS_ERROR");
    $config_handle->print(
        <<"_CONF_") or Carp::croak("Failed to print to $self->{_config_path}:$OS_ERROR");
\$ModLoad imuxsock
\$InputUnixListenSocketCreatePath on
\$AddUnixListenSocket $self->{_socket_path}
\$ActionFileDefaultTemplate RSYSLOG_TraditionalFileFormat
\$OmitLocalLogging off
*.* $self->{_messages_path}
_CONF_
    $config_handle->close()
      or Carp::croak("Failed to close $self->{_config_path}:$OS_ERROR");
    $self->start();
    return $self;
}

sub start {
    my ($self) = @_;
    my $dev_null = File::Spec->devnull();
    if ( ( defined $self->{_pid} ) && ( kill 0, $self->{_pid} ) ) {
        Carp::cluck('Temporary rsyslog daemon is already running...');
        return;
    }
    if ( $self->{_pid} = fork ) {
        while ( not -e $self->{_socket_path} ) {
            sleep 1;
        }
    }
    elsif ( defined $self->{_pid} ) {

        eval {
            # clear any possible tainted environment variables
            local %ENV = %ENV;
            local $ENV{'PATH'} = '/usr/bin:/usr/sbin:/sbin:/bin:';
            delete $ENV{'BASH_ENV'};
            delete $ENV{'ENV'};
            delete $ENV{'IFS'};
            delete $ENV{'CDPATH'};
            open STDERR, q[>], $dev_null
              or die "Failed to redirect STDERR:$OS_ERROR\n";
            open STDOUT, q[>], $dev_null
              or die "Failed to redirect STDOUT:$OS_ERROR\n";
            exec {'rsyslogd'} 'rsyslogd', '-n', '-d',
              '-f' => $self->{_config_path},
              '-i' => $self->{_pid_path}
              or die "Failed to exec 'rsyslogd':$OS_ERROR\n";
        } or do {
            chomp $EVAL_ERROR;
            warn "$EVAL_ERROR\n";
        };
        exit 1;
    }
    else {
        Carp::croak("Failed to fork:$OS_ERROR");
    }
    return;
}

sub stop {
    my ($self) = @_;
    if ( $self->{_pid} ) {
        my @signal_numbers = split q[ ], $Config{'sig_num'};
        my @signal_names   = split q[ ], $Config{'sig_name'};
        my %signals_by_name;
        my $signal_index = 0;
        foreach my $signal_name (@signal_names) {
            $signals_by_name{$signal_name} = $signal_numbers[$signal_index];
            $signal_index += 1;
        }
        if ( kill $signals_by_name{'TERM'}, $self->{_pid} ) {
            waitpid $self->{_pid}, 0;
        }
        elsif ( $OS_ERROR == POSIX::ESRCH() ) {
        }
        else {
            Carp::croak("Failed to kill $self->{_pid}:$OS_ERROR");
        }
    }
    return;
}

sub DESTROY {
    my ($self) = @_;
    $self->stop();
    foreach my $key ( sort { $a cmp $b } keys %{$self} ) {
        if ( $key =~ /_path$/smx ) {
            unlink $self->{$key}
              or ( $OS_ERROR == POSIX::ENOENT() )
              or Carp::croak("Failed to unlink $self->{$key}:$OS_ERROR");
        }
    }
    rmdir $self->{_root_directory}
      or ( $OS_ERROR == POSIX::ENOENT() )
      or Carp::croak("Failed to rmdir $self->{_root_directory}:$OS_ERROR");
    return;
}

1;
__END__