File Coverage

blib/lib/Test/Mojo/Role/SubmitForm.pm

Criterion	Covered	Total	%
statement	46	50	92.0
branch	28	30	93.3
condition	12	14	85.7
subroutine	6	6	100.0
pod	1	1	100.0
total	93	101	92.0

package Test::Mojo::Role::SubmitForm;

use Mojo::Base -base;
use Role::Tiny;
use Carp qw/croak/;

our $VERSION = '1.004002'; # VERSION

sub click_ok {
    my ( $self, $selector_or_dom, $extra_params ) = @_;
    $extra_params ||= {};

    my $el = eval { $selector_or_dom->isa('Mojo::DOM') }
        ? $selector_or_dom
        : $self->tx->res->dom->at($selector_or_dom)
            || croak 'Test::Mojo::Role::SubmitForm::click_ok()'
                . " Did not find element matching selector $selector_or_dom";
    unless ( $el->tag eq 'form' ) {
        if (length $el->{name}) {
            if ( ($el->{type}//'') eq 'image' ) {
                $extra_params->{ $el->{name} . '.x' } = 1;
                $extra_params->{ $el->{name} . '.y' } = 1;
            }
            else {
                $extra_params->{ $el->{name} } = $el->val;
            }
        }

        $el = $el->ancestors('form')->first;
    }

    for ( sort keys %$extra_params ) {
        next unless ref $extra_params->{$_} eq 'CODE';
        ( my $name = $_ ) =~ s/"/\\"/g;
        $extra_params->{$_} = $extra_params->{$_}->(
            $self->_gather_vals( $el->find(qq{[name="$name"]})->each )
        );
    }

    my %form = (
        $self->_get_controls($el),
        %$extra_params,
    );
    for (keys %form) {
        delete $form{$_} unless defined $form{$_}
    }

    if ( $ENV{MOJO_SUBMITFORM_DEBUG} ) {
        warn "\n########## SUBMITTING FORM ##########\n";
        require Mojo::Util;
        warn Mojo::Util::dumper(\%form);
        warn "##########    END FORM     ##########\n\n";
    }

    my $tx = $self->ua->build_tx(
        $el->{method}||'GET' => defined $el->{action} && $el->{action} ne '' ? $el->{action} : $self->tx->req->url
            => form => \%form,
    );

    $self->request_ok( $tx );
}

sub _gather_vals {
    my ( $self, @els ) = @_;
    my @vals;
    for ( @els ) {
        next if $_
        ->matches('[type=radio]:not(:checked), [type=checkbox]:not(:checked)');

        defined( my $val = $_->val ) or next;
        push @vals, ref $val ? @$val : $val;
    }
    return @vals == 1 ? $vals[0] : @vals ? \@vals : undef;
}

sub _get_controls {
    my ( $self, $form ) = @_;

    my @els = $form->find(
        'input:not([type=button]):not([type=submit]):not([type=image]),'       . 'select, textarea'
    )->each;

    my %controls;
    for ( @els ) {
        defined(my $vals = $self->_gather_vals( $_ )) or next;
        push @{ $controls{$_->{name}} }, ref $vals ? @$vals : $vals;
    }
    $#$_ or $_= $_->[0] for values %controls; # chage 1-el arrayrefs to strings

    return %controls;
}

q|
The fantastic element that explains the appeal of games to
many developers is neither the fire-breathing monsters nor the
milky-skinned, semi-clad sirens; it is the experience of
carrying out a task from start to finish without any change
in the user requirements.
|;

__END__