File Coverage

blib/lib/Test/JSYNC.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	6	8	75.0
condition	1	3	33.3
subroutine	9	9	100.0
pod	2	2	100.0
total	63	67	94.0

package Test::JSYNC;

use 5.006;
use strict;
use parent 'Test::Builder::Module';
use English qw( -no_match_vars );
use Carp;
use JSYNC;
use Test::Differences;

our $VERSION   = '0.02';
our @EXPORT    = qw( jsync_ok jsync_is );
our @EXPORT_OK = qw( is_valid_jsync is_jsync );

*is_valid_jsync = \&jsync_ok;
*is_jsync       = \&jsync_is;

sub jsync_ok ($;$) {
    my ($input, $test_name) = @_;
    my $test = __PACKAGE__->builder;

    croak 'usage: jsync_ok(input, test_name)'
        if !defined $input;

    eval { JSYNC::load($input) };

    if (my $error = $EVAL_ERROR) {
        $test->ok(0, $test_name);
        $test->diag("Input was not valid JSYNC: $error");
        return;
    }

    $test->ok(1, $test_name);
    return 1;
}

sub jsync_is ($$;$) {
    my ($input, $expected, $test_name) = @_;
    my $test = __PACKAGE__->builder;
    my %result_for;

    croak 'usage: jsync_is(input, expected, test_name)'
        if !defined $input || !defined $expected;

    for my $item (
        { key => 'input',    value => $input    },
        { key => 'expected', value => $expected },
    ) {
        $result_for{ $item->{key} } = eval { JSYNC::load( $item->{value} ) };

        if (my $error = $EVAL_ERROR) {
            $test->ok(0, $test_name);
            $test->diag(ucfirst "$item->{key} was not valid JSYNC: $error");
            return;
        }
    }

    local $Test::Builder::Level = $Test::Builder::Level + 1;

    return eq_or_diff($result_for{input}, $result_for{expected}, $test_name);
}

1;

__END__