File Coverage

blib/lib/Test/HexDifferences.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	18	22	81.8
condition	10	18	55.5
subroutine	8	8	100.0
pod	2	2	100.0
total	75	87	86.2

package Test::HexDifferences; ## no critic (TidyCode)

use strict;
use warnings;

use Sub::Exporter -setup => {
    exports => [
        qw(eq_or_dump_diff dumped_eq_dump_or_diff),
    ],
    groups  => {
        default => [ qw(eq_or_dump_diff dumped_eq_dump_or_diff) ],
    },
};
use Test::Builder::Module;
use Test::HexDifferences::HexDump qw(hex_dump);
use Text::Diff qw(diff);

our $VERSION = '1.000';

my $builder = Test::Builder->new;

my %diff_arg_of = (
    STYLE       => 'Table',
    INDEX_LABEL => 'Ln',
    FILENAME_A  => 'Got',
    FILENAME_B  => 'Expected',
);

sub eq_or_dump_diff ($$;$$) { ## no critic (SubroutinePrototypes)
    my ($got, $expected, @more) = @_;

    my $attr_ref
        = ( @more && ref $more[0] eq 'HASH' )
        ? shift @more
        : ();
    my $both_undefined
       = ! defined $got
       && ! defined $expected;
    my $any_undefined
       = ! defined $got
       || ! defined $expected;
    if ( $both_undefined || $any_undefined ) {
        my $result
            = $both_undefined
            || ! $any_undefined && $got eq $expected;
        $got      = defined $got      ? $got      : 'undef';
        $expected = defined $expected ? $expected : 'undef';
        my $ok = $builder->ok($result, $more[0])
            or $builder->diag(
                diff(
                    \$got,
                    \$expected,
                    \%diff_arg_of,
                ),
            );
        return $ok;
    }
    my $ok = $builder->ok($got eq $expected, $more[0])
        or $builder->diag(
            diff(
                \hex_dump($got, $attr_ref),
                \hex_dump($expected, $attr_ref),
                \%diff_arg_of,
            ),
        );

    return $ok;
}

sub dumped_eq_dump_or_diff ($$;$$) { ## no critic (SubroutinePrototypes)
    my ($got, $expected_dump, @more) = @_;

    my $attr_ref
        = ( @more && ref $more[0] eq 'HASH' )
        ? shift @more
        : ();
    $got = defined $got
        ? hex_dump($got, $attr_ref)
        : 'undef';
    $expected_dump = defined $expected_dump
        ? $expected_dump
        : 'undef';
    $expected_dump = defined $expected_dump ? $expected_dump : q{};
    my $ok = $builder->ok($got eq $expected_dump, $more[0])
        or $builder->diag(
            diff(
                \$got,
                \$expected_dump,
                \%diff_arg_of,
            ),
        );

    return $ok;
}

# $Id$

1;

__END__