File Coverage

blib/lib/TAP/Parser/SourceHandler/Handle.pm

Criterion	Covered	Total	%
statement	26	26	100.0
branch	5	6	83.3
condition	4	6	66.6
subroutine	8	8	100.0
pod	2	2	100.0
total	45	48	93.7

package TAP::Parser::SourceHandler::Handle;

use strict;
use warnings;

use TAP::Parser::IteratorFactory  ();
use TAP::Parser::Iterator::Stream ();

use base 'TAP::Parser::SourceHandler';

TAP::Parser::IteratorFactory->register_handler(__PACKAGE__);

=head1 NAME

TAP::Parser::SourceHandler::Handle - Stream TAP from an IO::Handle or a GLOB.

=head1 VERSION

Version 3.38

=cut

our $VERSION = '3.38';

=head1 SYNOPSIS

  use TAP::Parser::Source;
  use TAP::Parser::SourceHandler::Executable;

  my $source = TAP::Parser::Source->new->raw( \*TAP_FILE );
  $source->assemble_meta;

  my $class = 'TAP::Parser::SourceHandler::Handle';
  my $vote  = $class->can_handle( $source );
  my $iter  = $class->make_iterator( $source );

=head1 DESCRIPTION

This is a I L class.  It
has 2 jobs:

1. Figure out if the L it's given is an L or
GLOB containing raw TAP output (L).

2. Creates an iterator for IO::Handle's & globs (L).

Unless you're writing a plugin or subclassing L, you probably
won't need to use this module directly.

=head1 METHODS

=head2 Class Methods

=head3 C

  my $vote = $class->can_handle( $source );

Casts the following votes:

  0.9 if $source is an IO::Handle
  0.8 if $source is a glob

=cut

sub can_handle {
    my ( $class, $src ) = @_;
    my $meta = $src->meta;

    return 0.9
      if $meta->{is_object}
          && UNIVERSAL::isa( $src->raw, 'IO::Handle' );

    return 0.8 if $meta->{is_glob};

    return 0;
}

=head3 C

  my $iterator = $class->make_iterator( $source );

Returns a new L for the source.

=cut

sub make_iterator {
    my ( $class, $source ) = @_;

    $class->_croak('$source->raw must be a glob ref or an IO::Handle')
      unless $source->meta->{is_glob}
          || UNIVERSAL::isa( $source->raw, 'IO::Handle' );

    return $class->iterator_class->new( $source->raw );
}

=head3 C

The class of iterator to use, override if you're sub-classing.  Defaults
to L.

=cut

use constant iterator_class => 'TAP::Parser::Iterator::Stream';

1;

=head1 SUBCLASSING

Please see L for a subclassing overview.

=head1 SEE ALSO

L,
L,
L,
L,
L,
L,
L,
L,
L,
L

=cut