File Coverage

blib/lib/Test/GetVolatileData.pm

Criterion	Covered	Total	%
statement	32	34	94.1
branch	11	14	78.5
condition			n/a
subroutine	6	6	100.0
pod	1	1	100.0
total	50	55	90.9

package Test::GetVolatileData;

use 5.006;
use strict;
use warnings FATAL => 'all';

use LWP::UserAgent;
use Carp qw/croak/;
require Exporter;

our @ISA = qw(Exporter);
our @EXPORT = qw(get_data);

our $VERSION = '1.0102';

our $ERROR;

sub get_data {
    undef $ERROR;

    my $url = shift;
    my %args = @_;

    $args{num} = 1 unless exists $args{num};
    $args{num} =~ /\A\d+\z/
        or croak q{'num' argument can take only positive integers};

    my $res = LWP::UserAgent->new(
        agent   => 'Mozilla/5.0 (X11; Ubuntu; Linux i686; rv:26.0) '
            . 'Gecko/20100101 Firefox/26.0',
        timeout => 30,
    )->get( $url );

    unless ( $res->is_success ) {
        $ERROR = 'Network error: ' . $res->status_line;
        return;
    }

    my $c = $res->decoded_content;
    my @data = split /\n/, defined($c) ? $c : '';
    @data or do { $ERROR = 'Got empty data'; return };
    my @return;
    for ( 1.. $args{num} ) {
        @data or last;
        push @return, splice @data, int(rand @data), 1;
    }

    return @return > 1 ? @return : $return[0];
}


q|
Knock knock.

Race condition.

Who's there?
|;

__END__