File Coverage

blib/lib/Test/Fixture/KyotoTycoon.pm

Criterion	Covered	Total	%
statement	30	63	47.6
branch	0	14	0.0
condition	0	6	0.0
subroutine	10	16	62.5
pod	1	1	100.0
total	41	100	41.0

package Test::Fixture::KyotoTycoon;
use strict;
use warnings;
use 5.008000;
use parent qw(Exporter);
use Carp;
use Kwalify;
use Storable qw(nfreeze);
use YAML::XS qw(LoadFile);

our @EXPORT = qw(construct_fixture);
our $VERSION = '0.13';

sub construct_fixture {

	my %args = @_;
	my $fixture;

	if (!ref($args{kt}) || ref($args{kt}) && !$args{kt}->isa("Cache::KyotoTycoon")) {
		croak "kt must be Cache::KyotoTycoon instance";
	}

	if (-f $args{fixture}) {
		$fixture = LoadFile($args{fixture});
	} elsif (ref($args{fixture}) eq "ARRAY") {
		$fixture = $args{fixture};
	} else {
		croak "fixture must be YAML file path or ARRAY";
	}
	_validate_fixture($fixture);

	if (ref($args{serializer}) eq "CODE") {
		_override_serializer($args{serializer});
	}

	_delete_all($args{kt});
	return _insert($args{kt}, $fixture);
}

sub _delete_all {

	my $kt = shift;
	$kt->clear;
}

sub _insert {

	my($kt, $fixture) = @_;

	my $data = {};
	foreach my $ref (@{$fixture}) {

		my @values;
		push @values, (exists $ref->{namespace} ? sprintf("%s%s", $ref->{namespace}, $ref->{key}) : $ref->{key});
		push @values, (ref($ref->{value}) ? _serializer($ref->{value}) : $ref->{value});
		push @values, $ref->{xt} if exists $ref->{xt};
		#$kt->set($key, $value, $xt);
		$kt->set(@values);
		$data->{$values[0]} = $values[1];
	}
	return $data;
}

sub _override_serializer {

	my $serializer = shift;
	no strict "refs";
	no warnings "redefine";
	*_serializer = $serializer; ## no critic
}

sub _serializer {

	my $ref = shift;
	return nfreeze $ref;
}

sub _validate_fixture {

	my $stuff = shift;
	Kwalify::validate({
		type     => 'seq',
		sequence => [{
			type    => 'map',
			mapping => {
				namespace => { type => 'str' },
				key       => { type => 'str', required => 1 },
				value     => { type => 'any', required => 1 },
				xt        => { type => 'int' }
			},
		}]
	},
	$stuff
	);
	return $stuff;
}


1;
__END__