File Coverage

blib/lib/Test/Docker/MySQL.pm

Criterion	Covered	Total	%
statement	15	75	20.0
branch	0	14	0.0
condition			n/a
subroutine	5	13	38.4
pod	3	6	50.0
total	23	108	21.3

package Test::Docker::MySQL;
# ABSTRACT: Test::Docker::MySQL is a module to launch MySQL in docker containers.
use strict;
use constant DEBUG => $ENV{DEBUG_TEST_DOCKER_MYSQL};
our $VERSION = '0.02';
use DBI;
use IPC::Run ();
use Time::HiRes 'sleep';

sub WARN {
    my $msg = join " ",  @_;
    chomp $msg;
    warn sprintf "[%s %.5f] %s\n", __PACKAGE__, Time::HiRes::time, $msg;
}

sub new {
    my ($class, %args) = @_;

    my $tag   = delete $args{tag};
    my $ports = delete $args{ports};

    bless {
        tag           => defined $tag   ? $tag   : 'punytan/p5-test-docker-mysql',
        ports         => defined $ports ? $ports : [ 55500 .. 55555 ],
        container_ids => [],
    }, $class;
}

sub get_port {
    my $self = shift;
    $self->docker('ps'); # guarantee docker connection
    my $port = $self->find_port;
    return $port;
}

sub find_port {
    my $self = shift;

    while (1) {
        my $port = $self->{ports}[ int rand(scalar @{$self->{ports}}) ];
        DEBUG && WARN "trying port $port";
        my $container = eval { $self->docker(run => -p => "$port:3306", -d => $self->{tag}) };
        if (my $e = $@) {
            DEBUG && WARN "Failed to launch container: $e";
            next;
        } else {
            push @{$self->{container_ids}}, $container;
            eval { $self->_dbh($port) };
            if (my $e = $@) {
                DEBUG && WARN "Failed to get dbh: $e";
                next;
            } else {
                return $port;
            }
        }
    }

    die "Failed to allocate new container";
}

sub _dbh {
    my ($self, $port) = @_;

    my $dbh;

    while (not defined $dbh) {
        my $dsn = "dbi:mysql:database=mysql;host=127.0.0.1;port=$port";

        DEBUG && WARN "Connecting dsn: $dsn";

        $dbh = eval { DBI->connect($dsn, 'root', '', { RaiseError => 1 }) };
        if (my $e = $@) {
            DEBUG && WARN "Failed to connect mysql server: $e";
            sleep 0.2;
        }
    };

    DEBUG && WARN "Creating database: docker_mysql";
    eval { $dbh->do("CREATE DATABASE docker_mysql") };
    if (my $e = $@) {
        DEBUG && WARN "Failed to get lock (create database): $e";
        # Skip this container
    }

    DEBUG && WARN "Created database: docker_mysql";
}

sub docker {
    my ($self, $cmd, @args) = @_;
    $self->cmd(docker => $cmd, @args);
}

sub cmd {
    my ($self, @args) = @_;

    DEBUG && WARN sprintf "Run [ %s ]", join ' ', @args;
    my $is_success = IPC::Run::run [ @args ], \my $stdin, \my $stdout, \my $stderr;
    if ($is_success) {
        chomp $stdout;
        return $stdout;
    } else {
        die $stderr;
    }
}

sub DESTROY {
    my $self = shift;
    for my $container_id (@{$self->{container_ids}}) {
        DEBUG && WARN "Destroying container: $container_id";
        $self->docker(kill => $container_id);
    }
}

1;
__END__