File Coverage

lib/Test/Docker/Image.pm

Criterion	Covered	Total	%
statement	51	57	89.4
branch	8	10	80.0
condition	3	4	75.0
subroutine	12	14	85.7
pod	3	4	75.0
total	77	89	86.5

package Test::Docker::Image;

use strict;
use warnings;

use constant DEBUG => $ENV{DEBUG_TEST_DOCKER_IMAGE};

use IPC::Run3;
use Time::HiRes 'sleep';
use Data::Util ':check';
use Class::Load qw/try_load_class/;

use Class::Accessor::Lite (
    ro => [qw/tag container_ports container_id/],
);

our $VERSION = "0.03";

sub WARN {
    my $msg = join " ",  @_;
    chomp $msg;
    warn sprintf "[%s %.5f] %s\n", __PACKAGE__, Time::HiRes::time, $msg;
}

sub new {
    my $class = shift;
    my %args = @_ == 1 ? %{$_[0]} : @_;

    my $boot = delete $args{boot} || 'Test::Docker::Image::Boot';

    try_load_class( $boot ) or die "failed to load $boot";

    my $image_tag = delete $args{tag};
    die "tag argument is required" unless $image_tag;

    die "container_ports argument must be ArrayRef"
        unless is_array_ref $args{container_ports};

    my @ports = map { ('-p', $_) } @{ $args{container_ports} };
    my $container_id = _run(qw/docker run -d -t/, @ports, $image_tag);
    # wait to launch the container
    sleep $args{sleep_sec} || 0.5;

    my $self = bless {
        tag             => $image_tag,
        container_ports => $args{container_ports},
        container_id    => $container_id,
        boot            => $boot->new,
    }, $class;

    return $self;
}

sub port {
    my ($self, $container_port) = @_;
    my $port_info = _run(qw/docker port/, $self->container_id, $container_port);
    my (undef, $port) = split ':', $port_info;
    return $port;
}

sub host {
    $_[0]->{boot}->host;
}

sub _run {
    my (@cmd) = @_;

    DEBUG && WARN sprintf "Run [ %s ]", join ' ', @cmd;
    my $is_success = run3 [ @cmd ], \my $in, \my $out, \my $err;
    if ($is_success) {
        chomp $out;
        return $out;
    } else {
        die $err;
    }
}

sub DESTROY {
    my $self = shift;
    for my $subcommand ( qw/kill rm/ ) {
        _run('docker', $subcommand, $self->container_id);
    }
}

1;
__END__