File Coverage

blib/lib/Test/Deep/HashElements.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	6	10	60.0
condition			n/a
subroutine	12	12	100.0
pod	0	5	0.0
total	63	72	87.5

use strict;
use warnings;

package Test::Deep::HashElements 1.203;

use Test::Deep::Ref;

sub init
{
  my $self = shift;

  my $val = shift;

  $self->{val} = $val;
}

sub descend
{
  my $self = shift;

  my $got = shift;

  my $exp = $self->{val};

  my $data = $self->data;

  my $master = $self->getMaster($got, $exp);

  foreach my $key (sort keys %$master)
  {
    $data->{index} = $key;

    my $got_elem = exists $got->{$key} ? $got->{$key} : $Test::Deep::DNE;
    my $exp_elem = exists $exp->{$key} ? $exp->{$key} : $Test::Deep::DNE;

    next if Test::Deep::descend($got_elem, $exp_elem);

    return 0;
  }

  return 1;
}

sub getMaster
{
  my $self = shift;

  my ($got, $exp) = @_;

  return keys %$got > keys %$exp ? $got : $exp;
}

sub render_stack
{
  my $self = shift;
  my ($var, $data) = @_;
  $var .= "->" unless $Test::Deep::Stack->incArrow;
  $var .= '{"'.quotemeta($data->{index}).'"}';

  return $var;
}

sub reset_arrow
{
  return 0;
}

package Test::Deep::SuperHashElements 1.203;

use base 'Test::Deep::HashElements';

sub getMaster
{
  my $self = shift;

  my ($got, $exp) = @_;

  return $exp;
}

package Test::Deep::SubHashElements 1.203;

use base 'Test::Deep::HashElements';

sub getMaster
{
  my $self = shift;

  my ($got, $exp) = @_;

  return $got;
}

1;

__END__