File Coverage

blib/lib/Test/DBChanges/TableChangeSet.pm

Criterion	Covered	Total	%
statement	11	36	30.5
branch	0	6	0.0
condition	0	2	0.0
subroutine	4	11	36.3
pod	1	1	100.0
total	16	56	28.5

package Test::DBChanges::TableChangeSet;
use Moo;
use 5.024;
use Types::Standard qw(Str CodeRef ArrayRef HashRef);
use namespace::autoclean;

our $VERSION = '1.0.1'; # VERSION
# ABSTRACT: set of changes to one DB table


has table_name => ( is => 'ro', required => 1, isa => Str );
has source_name => ( is => 'ro', required => 1, isa => Str );
# how to turn the raw changes into the proper objects that the caller expects
has factory_sub => ( is => 'ro', required => 1, isa => CodeRef );
has _raw_changes => ( is => 'ro', required => 1, isa => ArrayRef[HashRef],
                      init_arg => 'raw_changes' );

has _raw_changes_by_operation => (
    is => 'lazy',
    builder => sub {
        my ($self) = @_;

        my %changes_by_operation;
        for my $change ($self->_raw_changes->@*) {
            push $changes_by_operation{$change->{operation}}->@*,
                $change;
        }

        return \%changes_by_operation;
    },
);

sub _make_row_objects {
    my ($self,$operation) = @_;

    return [ map {
        $self->factory_sub->($_->{data})
    } $self->_raw_changes_by_operation->{$operation}->@* ];
}


has inserted_rows => (
    is => 'lazy',
    builder => sub { shift->_make_row_objects('INSERT') },
);


has updated_rows => (
    is => 'lazy',
    builder => sub { shift->_make_row_objects('UPDATE') },
);


has deleted_rows => (
    is => 'lazy',
    builder => sub { shift->_make_row_objects('DELETE') },
);

sub _raw_combined_changes_data {
    my ($self,$key_column) = @_;
    $key_column //= 'id';

    my %data_by_key;
    for my $change ($self->_raw_changes->@*) {
        my $key = $change->{data}{$key_column};
        if ($change->{operation} eq 'INSERT') {
            $data_by_key{$key} = $change->{data};
        }
        elsif ($change->{operation} eq 'UPDATE') {
            my %data = $change->{data}->%*;
            $data_by_key{$key}
                ->@{ keys %data } = values %data;
        }
        elsif ($change->{operation} eq 'DELETE') {
            delete $data_by_key{$key};
        }
    }
    return [ values %data_by_key ];
}


sub combined_rows {
    my ($self,$key_column) = @_;

    return [ map {
        $self->factory_sub->($_)
    } $self->_raw_combined_changes_data($key_column)->@* ];
}

1;

__END__