File Coverage

blib/lib/Test/DBChanges/ChangeSet.pm

Criterion	Covered	Total	%
statement	14	29	48.2
branch			n/a
condition	0	2	0.0
subroutine	5	9	55.5
pod	1	1	100.0
total	20	41	48.7

package Test::DBChanges::ChangeSet;
use Moo;
use 5.024;
use Types::Standard qw(HashRef ArrayRef);
use Test::DBChanges::TableChangeSet;
use namespace::autoclean;
our $VERSION = '1.0.1'; # VERSION
# ABSTRACT: set of changes to DB tables


has table_source_map => ( is => 'ro', required => 1, isa => HashRef );
has _raw_changes => ( is => 'ro', required => 1, isa => ArrayRef[HashRef],
                      init_arg => 'raw_changes' );

has _raw_changes_for_table => (
    is => 'lazy',
    builder => sub {
        my ($self) = @_;

        my %changes_for_table;
        for my $change ($self->_raw_changes->@*) {
            push $changes_for_table{$change->{table_name}}->@*,
                $change;
        }

        return \%changes_for_table;
    },
);

has changed_tables => (
    is => 'lazy',
    builder => sub { return [ sort keys shift->_raw_changes_for_table->%* ] },
);

has _changes_for_source => (
    is => 'lazy',
    builder => sub {
        my ($self) = @_;
        my %changes_for_source;

        for my $table_name (keys $self->table_source_map->%*) {
            my $factory = $self->table_source_map->{$table_name}{factory};
            my $source_name = $self->table_source_map->{$table_name}{name};
            $changes_for_source{$source_name} = Test::DBChanges::TableChangeSet->new({
                table_name => $table_name,
                source_name => $source_name,
                factory_sub => $factory,
                raw_changes => $self->_raw_changes_for_table->{$table_name} // [],
            });
        }

        return \%changes_for_source;
    },
);



sub changes_for_source {
    my ($self,$source_name) = @_;
    return $self->_changes_for_source->{$source_name};
}

1;

__END__