File Coverage

blib/lib/Test/Clear.pm

Criterion	Covered	Total	%
statement	54	55	98.1
branch	8	10	80.0
condition	4	5	80.0
subroutine	14	14	100.0
pod	2	5	40.0
total	82	89	92.1

package Test::Clear;
use 5.008005;
use strict;
use warnings;
use parent 'Exporter';
use Test::More;
use Test::Builder;
use Data::Dumper;
use Scope::Guard;

our $VERSION = "0.03";
our @EXPORT = qw(case todo_scope todo_note);

sub dumper {
    my $value = shift;
    if ( not defined $value ) {
        return 'undef';
    }
    if ( defined $value && ref($value) ) {
        local $Data::Dumper::Terse = 1;
        local $Data::Dumper::Indent = 0;
        local $Data::Dumper::Sortkeys = 1;
        return Data::Dumper::Dumper($value);
    }
    return $value;
}

sub case {
    my ($caption, $dataset, $testcode, $opts) = @_;
    $dataset = (ref $dataset eq 'CODE') ? $dataset->(): $dataset;
    $caption = embeded($caption, $dataset);
    my $tb = Test::More->builder;
    return $tb->subtest($caption, $testcode, $dataset);
}

sub embeded {
    my ($caption, $dataset) = @_;
    return
        join '',
        map {
            /^\{(.+?)\}$/
                ? dumper($dataset->{$1})
                : $_
        }
        grep { defined && length }
        split /(\{.+?\})/, $caption;
}

sub todo_scope {
    my ($reason) = @_;
    my $tb = Test::More->builder;
    $tb->todo_start($reason);
    Scope::Guard->new(sub { $tb->todo_end });
}

sub todo_note {
    my ($caption, $reason) = @_;
    $reason ||= '';

    my (undef, $file, $line) = caller(0);
    $reason .= " [ $file line $line ]\n";

    my $tb = Test::More->builder;
    $tb->todo_start($reason);
    pass $caption;
    $tb->todo_end;
}

1;
__END__