File Coverage

blib/lib/Term/Vspark.pm

Criterion	Covered	Total	%
statement	51	54	94.4
branch	6	12	50.0
condition	8	16	50.0
subroutine	9	9	100.0
pod	1	3	33.3
total	75	94	79.7

package Term::Vspark;

use strict;
use warnings;
use POSIX;
use Carp qw{ croak };
use utf8;

use Sub::Exporter -setup => {
    'exports' => [ 'show_bar', 'show_graph', ],
};

our @ISA = qw();

our $VERSION = 0.31;

sub show_bar {
    my $num     = shift || 0;
    my $max     = shift || 0;
    my $columns = shift || 0;

    my @graph = qw{ ▏ ▎ ▍ ▌ ▋ ▊ ▉ █ };
    my $bar_num = ceil( $num * ( scalar(@graph) * $columns ) ) / $max;

    my $str = $graph[-1] x ( int($bar_num / scalar(@graph) ) );
    $str   .= $graph[ ceil($bar_num % (scalar(@graph) ) ) ];

    return $str;
}

sub show_graph {
    my %args = @_;

    if ( ref $args{'values'} ne 'ARRAY' ) {
        croak 'values is not an ArrayRef';
    }

    if ( $args{'labels'} && ( ref $args{'labels'} ne 'ARRAY' ) ) {
        croak 'labels is not an ArrayRef';
    }

    my $max     = $args{'max'}       || 1;
    my $columns = $args{'columns'}   || 1;
    my @labels  = @{ $args{'labels'} || [] };
    my @values  = @{ $args{'values'} };

    if ( $args{'labels'} && ( scalar @labels != scalar @values ) ) {
        croak 'the number of labels and values must be equal';
    }

    my $label_width = max_label_width( @labels );
    my $bar_width   = $columns - $label_width - 2;
    my $str         = q{};

    for my $value (@values) {
        my $label = shift @labels;
        my $bar   = show_bar($value, $max, $bar_width);

        $str .= sprintf('%' . $label_width . "s ", $label) if defined $label;
        $str .= $bar . "\n";
    }

    return $str;
}

sub max_label_width {
    my @labels = @_;
    return 0 if scalar @labels == 0;

    my $max_width = (sort { $a <=> $b } map { length($_) } @labels)[-1];
    return $max_width + 1;
}

1;
__END__