File Coverage

blib/lib/Term/Table/CellStack.pm

Criterion	Covered	Total	%
statement	49	55	89.0
branch	2	2	100.0
condition	1	2	50.0
subroutine	14	16	87.5
pod	0	8	0.0
total	66	83	79.5

package Term::Table::CellStack;
use strict;
use warnings;

our $VERSION = '0.015';

use Term::Table::HashBase qw/-cells -idx/;

use List::Util qw/max/;

sub init {
    my $self = shift;
    $self->{+CELLS} ||= [];
}

sub add_cell {
    my $self = shift;
    push @{$self->{+CELLS}} => @_;
}

sub add_cells {
    my $self = shift;
    push @{$self->{+CELLS}} => @_;
}

sub sanitize {
    my $self = shift;
    $_->sanitize(@_) for @{$self->{+CELLS}};
}

sub mark_tail {
    my $self = shift;
    $_->mark_tail(@_) for @{$self->{+CELLS}};
}

my @proxy = qw{
    border_left border_right border_color value_color reset_color
    border_left_width border_right_width
};

for my $meth (@proxy) {
    no strict 'refs';
    *$meth = sub {
        my $self = shift;
        $self->{+CELLS}->[$self->{+IDX}]->$meth;
    };
}

for my $meth (qw{value_width width}) {
    no strict 'refs';
    *$meth = sub {
        my $self = shift;
        return max(map { $_->$meth } @{$self->{+CELLS}});
    };
}

sub next {
    my $self = shift;
    my ($cw) = @_;

    while ($self->{+IDX} < @{$self->{+CELLS}}) {
        my $cell = $self->{+CELLS}->[$self->{+IDX}];

        my $lw = $cell->border_left_width;
        my $rw = $cell->border_right_width;
        my $vw = $cw - $lw - $rw;
        my $it = $cell->break->next($vw);

        return ($it, $vw) if $it;
        $self->{+IDX}++;
    }

    return;
}

sub break { $_[0] }

sub reset {
    my $self = shift;
    $self->{+IDX} = 0;
    $_->reset for @{$self->{+CELLS}};
}

1;

__END__