File Coverage

blib/lib/Teng/Plugin/Pager/DataPageset.pm

Criterion	Covered	Total	%
statement	21	37	56.7
branch	0	10	0.0
condition	0	11	0.0
subroutine	7	8	87.5
pod	1	1	100.0
total	29	67	43.2

package Teng::Plugin::Pager::DataPageset;
use 5.008005;

use strict;
use warnings;
use utf8;
use Data::Pageset;
use Teng::Iterator;
use Carp ();

our $VERSION = "0.01";

our @EXPORT = qw/search_with_data_pageset/;

sub search_with_data_pageset {
    my ($self, $table_name, $where, $opt) = @_;

    my $table = $self->schema->get_table($table_name) or Carp::croak("'$table_name' is unknown table");

    my $page  = $opt->{page} || 1;
    my $rows  = $opt->{rows} || 1;
    my $mode  = $opt->{mode} || 'fixed';
    my $pages_per_set = $opt->{pages_per_set} || 5;
    my $total_entries = $opt->{total_entries} or Carp::croak("please input 'total_entries' option");

    my $columns = $opt->{'+columns'} ? [@{$table->{columns}}, @{$opt->{'+columns'}}]
                                     : ($opt->{columns} || $table->{columns})
                                     ;

    my ($sql, @binds) = $self->sql_builder->select(
        $table_name,
        $columns,
        $where, +{
            %$opt,
            limit  => $rows,
            offset => $rows*($page-1),
        },
    );
    my $sth = $self->dbh->prepare($sql) or Carp::croak $self->dbh->errstr;
    $sth->execute(@binds) or Carp::croak $self->dbh->errstr;

    my $itr = Teng::Iterator->new(
        teng             => $self,
        sth              => $sth,
        sql              => $sql,
        row_class        => $self->schema->get_row_class($table_name),
        table            => $table,
        table_name       => $table_name,
        suppress_object_creation => $self->suppress_row_objects,
    );

    my $pager = Data::Pageset->new({
        'total_entries'       => $total_entries,
        'entries_per_page'    => $rows,
        'current_page'        => $page,
        'pages_per_set'       => $pages_per_set,
        'mode'                => $mode,
    });

    return ([$itr->all], $pager);
}

1;

__END__