File Coverage

blib/lib/Template/Sandbox/Library.pm

Criterion	Covered	Total	%
statement	55	55	100.0
branch	22	22	100.0
condition	4	11	36.3
subroutine	9	9	100.0
pod	3	3	100.0
total	93	100	93.0

package Template::Sandbox::Library;

use strict;
use warnings;

use Carp;

use Template::Sandbox;

my %function_library = ();
my %function_tags    = ();

BEGIN
{
    $Template::Sandbox::Library::VERSION = '1.04';
}

sub import
{
    my $pkg = shift;

    export_template_functions( $pkg, 'Template::Sandbox', @_ ) if @_;
}

sub export_template_functions
{
    my ( $this, $template, @imports ) = @_;
    my ( $pkg, $library, $tags, %export, @functions, $existing );

    $pkg = ref( $this ) || $this;

    croak "\"$pkg\" does not appear to be a template function library."
        unless $function_library{ $pkg };

    $library = $function_library{ $pkg };
    $tags    = $function_tags{ $pkg };

    %export = ();
    foreach my $import ( @imports )
    {
        foreach my $word ( split( /\s+/, $import ) )
        {
            my ( $delete );

            $delete = 1 if $word =~ s/^!//;

            if( $word =~ s/^:// )
            {
                my ( @names );

                if( exists $tags->{ $word } )
                {
                    @names = @{$tags->{ $word }};
                }
                elsif( $word eq 'all' )
                {
                    @names = keys( %{$library} );
                }
                else
                {
                    croak "\"$word\" is not a template library tag in $pkg";
                }

                if( $delete )
                {
                    delete $export{ $_ } foreach ( @names );
                }
                else
                {
                    $export{ $_ } = 1 foreach ( @names );
                }
            }
            else
            {
                if( $delete )
                {
                    delete $export{ $word };
                }
                else
                {
                    $export{ $word } = 1;
                }
            }
        }
    }

    $existing = $template->_find_local_functions();

    @functions = ();
    foreach my $name ( keys( %export ) )
    {
        croak "\"$name\" is not a template library function in $pkg"
            unless $library->{ $name };

        push @functions, $name => $library->{ $name }
            unless exists $existing->{ $name };
    }

    $template->register_template_function( @functions ) if @functions;
}

sub set_library_functions
{
    my ( $this, %functions ) = @_;
    my ( $pkg );

    $pkg = ref( $this ) || $this;

    $function_library{ $pkg } = \%functions;
    $function_tags{ $pkg } ||= {};
}

sub set_library_tags
{
    my ( $this, %tags ) = @_;
    my ( $pkg );

    $pkg = ref( $this ) || $this;

    $function_tags{ $pkg } = \%tags;
}

1;

__END__