File Coverage

blib/lib/Template/Plugin/ArrayRef.pm

Criterion	Covered	Total	%
statement	45	47	95.7
branch	5	10	50.0
condition			n/a
subroutine	11	11	100.0
pod	2	3	66.6
total	63	71	88.7

package Template::Plugin::ArrayRef;
use base 'Template::Plugin';
use strict;
use warnings;
use Template::Exception;
use Scalar::Util qw();

our $VERSION   = 0.11;
our $MONAD     = 'Template::Monad::ArrayRef';
our $EXCEPTION = 'Template::Exception';
our $AUTOLOAD;

sub load {
    my $class   = shift;
    my $context = shift;

    # define .arrayref vmethods for hash and list objects
    $context->define_vmethod( hash => arrayref => \&arrayref_monad );
    $context->define_vmethod( list => arrayref => \&arrayref_monad );

    return $class;
}

sub arrayref_monad {
    # create a .arrayref monad which wraps the hash- or list-based object
    # and delegates any method calls back to it, calling them in scalar
    # context, e.g. foo.arrayref.bar becomes $MONAD->new($foo)->bar and
    # the monad calls $foo->bar in array context
    $MONAD->new(shift);
}

sub new {
    my ($class, $context, @args) = @_;
    # create a scalar plugin object which will lookup a variable subroutine
    # and call it.  e.g. arrayref.foo results in a call to foo() in array context
    my $self = bless {
        _CONTEXT => $context,
    }, $class;
    return $self;
}

sub AUTOLOAD {
    my $self = shift;
    my $item = $AUTOLOAD;
    $item =~ s/.*:://;
    return if $item eq 'DESTROY';

    # lookup the named values
    my $stash = $self->{ _CONTEXT }->stash;
    my $value = $stash->{ $item };

    if (! defined $value) {
        die $EXCEPTION->new( arrayref => "undefined value for arrayref call: $item" );
    }
    elsif (ref $value eq 'CODE') {
        $value = [ $value->(@_) ];
    }
    return $value;
}


package Template::Monad::ArrayRef;

our $EXCEPTION = 'Template::Exception';
our $AUTOLOAD;

sub new {
    my ($class, $this) = @_;
    bless \$this, $class;
}

sub AUTOLOAD {
    my $self = shift;
    my $this = $$self;
    my $item = $AUTOLOAD;
    $item =~ s/.*:://;
    return if $item eq 'DESTROY';

    my $method;
    if (Scalar::Util::blessed($this)) {
        # lookup the method...
        $method = $this->can($item);
    }
    else {
        die $EXCEPTION->new( arrayref => "invalid object method: $item" );
    }

    # ...and call it in array context
    my @results = $method->($this, @_);
    return \@results;
}

1;

__END__