File Coverage

blib/lib/Tangerine/hook/list.pm

Criterion	Covered	Total	%
statement	65	65	100.0
branch	22	24	91.6
condition	13	14	92.8
subroutine	14	14	100.0
pod	1	1	100.0
total	115	118	97.4

package Tangerine::hook::list;
$Tangerine::hook::list::VERSION = '0.20';
use 5.010;
use strict;
use warnings;
use parent 'Tangerine::Hook';
use List::Util 1.33 qw(any);
use Tangerine::HookData;
use Tangerine::Occurence;
use Tangerine::Utils qw(stripquotelike $vre);

sub run {
    my ($self, $s) = @_;
    if ((any { $s->[0] eq $_ } qw(use no)) && scalar(@$s) > 2 &&
        (any { $s->[1] eq $_ }
            qw(aliased base mixin::with Mojo::Base ok parent superclass
               Test::Class::Most))) {
        my ($version) = $s->[2] =~ $vre;
        $version //= '';
        my $voffset = $version ? 3 : 2;
        my @args;
        if (scalar(@$s) > $voffset) {
            return if $s->[$voffset] eq ';';
            @args = @$s;
            @args = @args[($voffset) .. $#args];
            @args = stripquotelike(@args);
            @args = grep { !/^-norequire$/ } @args
                if any { $s->[1] eq $_ } qw/parent superclass/;
            @args = grep { !/^-(base|strict)$/ } @args
                if $s->[1] eq 'Mojo::Base';
        }
        @args = $args[0]
            if $args[0] && any { $s->[1] eq $_ } qw/aliased mixin::with Mojo::Base ok/;
        if ($s->[1] eq 'Test::Class::Most') {
            my $tcmparent;
            my @results;
            for my $arg (@args) {
                if ($tcmparent) {
                    if (any { $arg eq $_ } qw/attributes is_abstract/) {
                        undef $tcmparent;
                        next
                    }
                    push @results, $arg
                } else {
                    if ($arg eq 'parent') {
                        $tcmparent++;
                        undef @results
                    }
                }
            }
            @args = @results
        }
        my %found;
        for (my $i = 0; $i < scalar(@args); $i++) {
            $found{$args[$i]} = '';
            if ($args[$i+1] && $args[$i+1] =~ /^v?\d+(?:\.\d+)*$/) {
                $found{$args[$i]} = $args[$i+1];
                $i++
            }
        }
        return Tangerine::HookData->new(
            modules => {
                map {
                    ( $_ => Tangerine::Occurence->new(version => $found{$_}) )
                    } keys %found,
                },
            );
    }
    return;
}

1;

__END__