File Coverage

blib/lib/Tags/HTML/SendMessage.pm

Criterion	Covered	Total	%
statement	15	44	34.0
branch	0	14	0.0
condition	0	6	0.0
subroutine	5	9	55.5
pod	2	2	100.0
total	22	75	29.3

package Tags::HTML::SendMessage;

use strict;
use warnings;

use Class::Utils qw(set_params);
use Error::Pure qw(err);
use Readonly;

# Constants.
Readonly::Hash my %LANG => (
	'title' => 'Leave us a message',
	'name-and-surname' => 'Name and surname',
	'email' => 'Email',
	'subject' => 'Subject of you question',
	'your-message' => 'Your message',
	'send' => 'Send question',
);

our $VERSION = 0.09;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# 'CSS::Struct' object.
	$self->{'css'} = undef;

	# Languages.
	$self->{'lang'} = \%LANG;

	# 'Tags' object.
	$self->{'tags'} = undef;

	# Process params.
	set_params($self, @params);

	# Check to 'Tags' object.
	if (! $self->{'tags'} || ! $self->{'tags'}->isa('Tags::Output')) {
		err "Parameter 'tags' must be a 'Tags::Output::*' class.";
	}

	# Check to 'CSS::Struct' object.
	if ($self->{'css'} && ! $self->{'css'}->isa('CSS::Struct::Output')) {
		err "Parameter 'css' must be a 'CSS::Struct::Output::*' class.";
	}

	# Object.
	return $self;
}

# Process 'Tags'.
sub process {
	my $self = shift;

	# Begin of page.
	$self->{'tags'}->put(
		['b', 'div'],
		['a', 'id', 'send-message'],

		['b', 'form'],
		['a', 'action', ''],

		['b', 'fieldset'],

		['b', 'legend'],
		['d', $self->{'lang'}->{'title'}],
		['e', 'legend'],
	);
	$self->_tags_form_input('name-and-surname', 1, { 'size' => 30 });
	$self->_tags_form_input('email', 1, { 'size' => 30 });
	$self->_tags_form_input('subject', 1, { 'size' => 72 });
	$self->_tags_form_textarea('your-message', 1, { 'cols' => 75, 'rows' => 10 });
	$self->{'tags'}->put(

		['b', 'input'],
		['a', 'type', 'submit'],
		['a', 'value', $self->{'lang'}->{'send'}],
		['e', 'input'],

		['e', 'fieldset'],
		['e', 'form'],
		['e', 'div'],
	);

	return;
}

sub _tags_form_input {
	my ($self, $id, $br, $input_opts_hr) = @_;

	$self->{'tags'}->put(
		['b', 'label'],
		['a', 'for', $id],
		['d', $self->{'lang'}->{$id}.':'],
		['e', 'label'],

		['b', 'br'],
		['e', 'br'],

		['b', 'input'],
		['a', 'id', $id],
		['a', 'name', $id],
		exists $input_opts_hr->{'size'} ? (
			['a', 'size', $input_opts_hr->{'size'}],
		) : (),
		['e', 'input'],
	);
	if ($br) {
		$self->{'tags'}->put(
			['b', 'br'],
			['e', 'br'],
		);
	}

	return;
}

sub _tags_form_textarea {
	my ($self, $id, $br, $textarea_opts_hr) = @_;

	$self->{'tags'}->put(
		['b', 'label'],
		['a', 'for', $id],
		['d', $self->{'lang'}->{$id}.':'],
		['e', 'label'],

		['b', 'br'],
		['e', 'br'],

		['b', 'textarea'],
		['a', 'id', $id],
		['a', 'name', $id],
		exists $textarea_opts_hr->{'cols'} ? (
			['a', 'cols', $textarea_opts_hr->{'cols'}],
		) : (),
		exists $textarea_opts_hr->{'rows'} ? (
			['a', 'rows', $textarea_opts_hr->{'rows'}],
		) : (),
		['e', 'textarea'],
	);
	if ($br) {
		$self->{'tags'}->put(
			['b', 'br'],
			['e', 'br'],
		);
	}

	return;
}

1;

__END__