File Coverage

blib/lib/TablesRole/Util/Random.pm

Criterion	Covered	Total	%
statement	24	24	100.0
branch	8	10	80.0
condition			n/a
subroutine	6	6	100.0
pod	4	4	100.0
total	42	44	95.4

package TablesRole::Util::Random;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2020-11-10'; # DATE
our $DIST = 'TablesRoles-Standard'; # DIST
our $VERSION = '0.006'; # VERSION

# enabled by Role::Tiny
#use strict;
#use warnings;

use Role::Tiny;

requires 'get_row_arrayref';
requires 'get_row_hashref';

sub _get_rand_rows {
    my ($self, $type, $num_items) = @_;
    my @items;
    my $i = -1;
    $self->reset_iterator;
    my $meth = $type eq 'arrayref' ? 'get_row_arrayref' : 'get_row_hashref';
    while (defined(my $item = $self->$meth)) {
        $i++;
        if (@items < $num_items) {
            # we haven't reached $num_items, insert item to array in a random
            # position
            splice @items, rand(@items+1), 0, $item;
        } else {
            # we have reached $num_items, just replace an item randomly, using
            # algorithm from Learning Perl, slightly modified
            rand($i+1) < @items and splice @items, rand(@items), 1, $item;
        }
    }
    \@items;
}

sub get_rand_row_arrayref {
    my $self = shift;
    my $rows = $self->get_rand_rows_arrayref(1);
    $rows ? $rows->[0] : undef;
}

sub get_rand_rows_arrayref {
    my ($self, $n) = @_;
    $self->_get_rand_rows('arrayref', $n);
}

sub get_rand_row_hashref {
    my $self = shift;
    my $rows = $self->get_rand_rows_hashref(1);
    $rows ? $rows->[0] : undef;
}

sub get_rand_rows_hashref {
    my ($self, $n) = @_;
    $self->_get_rand_rows('hashref', $n);
}

1;
# ABSTRACT: Provide utility methods related to getting random rows

__END__