File Coverage

blib/lib/TableDataRole/Source/CSVInFiles.pm

Criterion	Covered	Total	%
statement	83	92	90.2
branch	16	28	57.1
condition			n/a
subroutine	12	13	92.3
pod	2	9	22.2
total	113	142	79.5

package TableDataRole::Source::CSVInFiles;

use 5.010001;
use strict;
use warnings;

use Role::Tiny;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2023-06-14'; # DATE
our $DIST = 'TableDataRoles-Standard'; # DIST
our $VERSION = '0.016'; # VERSION

with 'TableDataRole::Spec::Basic';

sub new {
    require Text::CSV_XS;

    my ($class, %args) = @_;

    my $fhs = [];
    if (defined(my $filenames = delete $args{filenames})) {
        for my $filename (@$filenames) {
            open my $fh, "<", $filename
                or die "Can't open file '$filename': $!";
            push @$fhs, $fh;
        }
    } elsif (defined($fhs = delete $args{filehandles})) {
    } else {
        die "Please specify 'filenames' or 'filehandles'";
    }
    @$fhs or die "Please supply at least one filename/filehandle";
    die "Unknown argument(s): ". join(", ", sort keys %args)
        if keys %args;

    my $csv_parser = Text::CSV_XS->new({binary=>1});

    my $files = [];
    my $columns;
    for my $fh (@$fhs) {
        my $fhpos_data_begin = tell $fh;
        $columns = $csv_parser->getline($fh)
            or die "Can't read columns from first row of CSV file";
        my $fhpos_datarow_begin = tell $fh;
        push @$files, {
            fh => $fh,
            fhpos_data_begin => $fhpos_data_begin,
            fhpos_datarow_begin => $fhpos_datarow_begin,
        };
    }
    bless {
        files => $files,
        csv_parser => $csv_parser,
        columns => $columns,
        file_pos => 0, # which file are we at
        pos => 0, # iterator
    }, $class;
}

sub as_csv {
    my $self = shift;

    my $res = "";
    for my $i (0 .. $#{$self->{files}}) {
        my $file = $self->{files}[$i];
        my $fh = $file->{fh};
        my $oldpos = tell $fh;
        seek $fh, ($i ? $file->{fhpos_datarow_begin} : $file->{fhpos_data_begin}), 0;
        local $/;
        $res .= scalar <$fh>;
    }
    $self->{pos} = 0;
    $self->{file_pos} = 0;
    $res;
}

sub get_column_count {
    my $self = shift;

    scalar @{ $self->{columns} };
}

sub get_column_names {
    my $self = shift;
    wantarray ? @{ $self->{columns} } : $self->{columns};
}

sub has_next_item {
    my $self = shift;
    my $files = $self->{files};
    my $seek = 0;
    while (1) {
        my $file = $self->{files}[$self->{file_pos}];
        my $fh = $file->{fh};
        if ($seek) {
            seek $fh, $file->{fhpos_datarow_begin}, 0;
            $seek = 0;
        }
        return 1 unless eof($fh);
        return 0 if $self->{file_pos} >= $#{$self->{files}};
        $self->{file_pos}++;
        $seek++;
    }
}

sub get_next_item {
    my $self = shift;
    my $files = $self->{files};
    my $seek = 0;
    while (1) {
        my $file = $self->{files}[$self->{file_pos}];
        my $fh = $file->{fh};
        if ($seek) {
            seek $fh, $file->{fhpos_datarow_begin}, 0;
            $seek = 0;
        }
        unless (eof($fh)) {
            my $row = $self->{csv_parser}->getline($fh);
            $self->{pos}++;
            return $row;
        }
        die "StopIteration" if $self->{file_pos} >= $#{$self->{files}};
        $self->{file_pos}++;
        $seek++;
    }
}

sub get_next_row_hashref {
    my $self = shift;
    my $row = $self->get_next_item;
    +{ map {($self->{columns}[$_] => $row->[$_])} 0..$#{$self->{columns}} };
}

sub get_iterator_pos {
    my $self = shift;
    $self->{pos};
}

sub reset_iterator {
    my $self = shift;
    $self->{file_pos} = 0;
    my $fh = $self->{files}[0]{fh};
    seek $fh, $self->{files}[0]{fhpos_datarow_begin}, 0;
    $self->{pos} = 0;
}

1;
# ABSTRACT: Role to access table data from CSV in a set of files/filehandles

__END__