File Coverage

blib/lib/TableDataRole/Source/CSVInFile.pm

Criterion	Covered	Total	%
statement	59	62	95.1
branch	10	16	62.5
condition			n/a
subroutine	13	14	92.8
pod	2	9	22.2
total	84	101	83.1

package TableDataRole::Source::CSVInFile;

use 5.010001;
use strict;
use warnings;

use Role::Tiny;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2022-02-20'; # DATE
our $DIST = 'TableDataRoles-Standard'; # DIST
our $VERSION = '0.014'; # VERSION

with 'TableDataRole::Spec::Basic';

sub new {
    require Text::CSV_XS;

    my ($class, %args) = @_;

    my $fh;
    if (defined(my $filename = delete $args{filename})) {
        open $fh, "<", $filename
            or die "Can't open file '$filename': $!";
    } elsif (defined($fh = delete $args{filehandle})) {
    } else {
        die "Please specify 'filename' or 'filehandle'";
    }
    die "Unknown argument(s): ". join(", ", sort keys %args)
        if keys %args;

    my $csv_parser = Text::CSV_XS->new({binary=>1});

    my $fhpos_data_begin = tell $fh;
    my $columns = $csv_parser->getline($fh)
        or die "Can't read columns from first row of CSV file";
    my $fhpos_datarow_begin = tell $fh;

    bless {
        fh => $fh,
        fhpos_data_begin => $fhpos_data_begin,
        fhpos_datarow_begin => $fhpos_datarow_begin,
        csv_parser => $csv_parser,
        columns => $columns,
        pos => 0, # iterator
    }, $class;
}

sub as_csv {
    my $self = shift;

    my $fh = $self->{fh};
    my $oldpos = tell $fh;
    seek $fh, $self->{fhpos_data_begin}, 0;
    $self->{pos} = 0;
    local $/;
    scalar <$fh>;
}

sub get_column_count {
    my $self = shift;

    scalar @{ $self->{columns} };
}

sub get_column_names {
    my $self = shift;
    wantarray ? @{ $self->{columns} } : $self->{columns};
}

sub has_next_item {
    my $self = shift;
    my $fh = $self->{fh};
    !eof($fh);
}

sub get_next_item {
    my $self = shift;
    my $fh = $self->{fh};
    die "StopIteration" if eof($fh);
    my $row = $self->{csv_parser}->getline($fh);
    $self->{pos}++;
    $row;
}

sub get_next_row_hashref {
    my $self = shift;
    my $fh = $self->{fh};
    die "StopIteration" if eof($fh);
    my $row = $self->{csv_parser}->getline($fh);
    $self->{pos}++;
    +{ map {($self->{columns}[$_] => $row->[$_])} 0..$#{$self->{columns}} };
}

sub get_iterator_pos {
    my $self = shift;
    $self->{pos};
}

sub reset_iterator {
    my $self = shift;
    my $fh = $self->{fh};
    seek $fh, $self->{fhpos_datarow_begin}, 0;
    $self->{pos} = 0;
}

sub DESTROY {
    my $self = shift;
    my $fh = $self->{fh};
    seek $fh, $self->{fhpos_data_begin}, 0;
}

1;
# ABSTRACT: Role to access table data from CSV in a file/filehandle

__END__