File Coverage

blib/lib/TAP/Spec/TestSet.pm

Criterion	Covered	Total	%
statement	29	31	93.5
branch	5	8	62.5
condition			n/a
subroutine	8	9	88.8
pod	2	2	100.0
total	44	50	88.0

package TAP::Spec::TestSet;
BEGIN {
  $TAP::Spec::TestSet::AUTHORITY = 'cpan:ARODLAND';
}
{
  $TAP::Spec::TestSet::VERSION = '0.10';
}
# ABSTRACT: A set of related TAP tests
use Mouse;
use namespace::autoclean;

use TAP::Spec::Body ();
use TAP::Spec::Plan ();
use TAP::Spec::Header ();
use TAP::Spec::Footer ();


has 'body' => (
  is => 'rw',
  isa => 'TAP::Spec::Body',
  handles => {
    lines => 'lines',
    tests => 'tests',
    body_comments => 'comments',
  },
  required => 1,
);


has 'plan' => (
  is => 'rw',
  isa => 'TAP::Spec::Plan',
);


has version => (
    is          => 'rw',
    isa         => 'Int',
    lazy        => 1,
    default     => sub {
        my $self = shift;

        if( my $v = $self->header->version ) {
            return $v->version_number;
        }
        else {
            return 12;
        }
    }
);


has 'header' => (
  is => 'rw',
  isa => 'TAP::Spec::Header',
  handles => {
    header_comments => 'comments',
  },
  required => 1,
);


has 'footer' => (
  is => 'rw',
  isa => 'TAP::Spec::Footer',
  handles => {
    footer_comments => 'comments',
  },
  required => 1,
);


sub as_tap {
  my ($self) = @_;

  return $self->plan->as_tap()   .
         $self->header->as_tap() .
         $self->body->as_tap()   .
         $self->footer->as_tap();
}


sub passed {
    my $self = shift;

    return '' unless $self->plan;
    my $expected = $self->plan->number_of_tests;

    my @tests = $self->tests;
    return '' unless @tests == $expected;

    my $count = 1;
    for my $test (@tests) {
        return '' unless $test->passed;
        return '' unless $test->number == $count++;
    }

    return 1;
}

__PACKAGE__->meta->make_immutable;

__END__