File Coverage

blib/lib/System/Introspector/Probe/Sudoers.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch	6	8	75.0
condition	1	3	33.3
subroutine	7	7	100.0
pod	0	1	0.0
total	48	53	90.5

package System::Introspector::Probe::Sudoers;
use Moo;

use System::Introspector::Util qw(
    handle_from_command
    files_from_dir
    output_from_file
    transform_exceptions
);

has sudoers_file => (
    is      => 'ro',
    default => sub { '/etc/sudoers' },
);

has hostname => (
    is      => 'ro',
    default => sub { scalar `hostname` },
);

sub gather {
    my ($self) = @_;
    my %file = $self->_gather_files($self->sudoers_file);
    return \%file;
}

sub _gather_files {
    my ($self, $file) = @_;
    my $result = transform_exceptions {
        my @lines = output_from_file $file;
        my @result = ({ body => join '', @lines });
        for my $line (@lines) {
            chomp $line;
            if ($line =~ m{^#include\s+(.+)$}) {
                my $inc_file = $self->_insert_hostname($1);
                push @result, $self->_gather_files($inc_file);
            }
            elsif ($line =~ m{^#includedir\s+(.+)$}) {
                my $inc_dir = $self->_insert_hostname($1);
                push @result, $self->_gather_from_dir($inc_dir);
            }
        }
        return \@result;
    };
    return $file => $result
        if ref $result eq 'HASH';
    return $file => @$result;
}

sub _gather_from_dir {
    my ($self, $dir) = @_;
    my @files = files_from_dir $dir;
    my %file;
    for my $file (@files) {
        next if $file =~ m{\.} or $file =~ m{~$};
        %file = (%file, $self->_gather_files("$dir/$file"));
    }
    return %file;
}

sub _insert_hostname {
    my ($self, $value) = @_;
    my $hostname = $self->hostname;
    $value =~ s{\%h}{$hostname}g;
    return $value;
}

1;

__END__