File Coverage

blib/lib/Types/Sub.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch	4	4	100.0
condition			n/a
subroutine	13	13	100.0
pod			n/a
total	55	55	100.0

package Types::Sub;
use 5.010;
use strict;
use warnings;

our $VERSION = "0.15";

use Sub::Meta;
use Sub::Meta::Type;
use Sub::Meta::TypeSub;
use Sub::Meta::CreatorFunction;

use Types::Standard qw(Ref);
use Type::Library
    -base,
    -declare => qw(
        Sub
        StrictSub
        SubMeta
        StrictSubMeta
    );

__PACKAGE__->meta->add_type(
    name   => 'Sub',
    constraint_generator => _gen_sub_constraint_generator(strict => 0),
);

__PACKAGE__->meta->add_type(
    name   => 'StrictSub',
    constraint_generator => _gen_sub_constraint_generator(strict => 1),
);

__PACKAGE__->meta->add_type(
    name => 'SubMeta',
    constraint_generator => _gen_submeta_constraint_generator(strict => 0),
);

__PACKAGE__->meta->add_type(
    name => 'StrictSubMeta',
    constraint_generator => _gen_submeta_constraint_generator(strict => 1),
);

sub _gen_sub_constraint_generator {
    my (%options) = @_;
    my $strict = $options{strict};

    my $CodeRef = Ref['CODE'];

    return sub {
        return $CodeRef unless @_;

        my $SubMeta = $strict ? StrictSubMeta[@_] : SubMeta[@_];

        return Sub::Meta::TypeSub->new(
            parent       => $CodeRef,
            submeta_type => $SubMeta
        )
    }
}

sub _gen_submeta_constraint_generator {
    my (%options) = @_;
    my $strict = $options{strict};

    return sub {
        my $submeta = Sub::Meta->new(@_);

        return Sub::Meta::Type->new(
            submeta              => $submeta,
            submeta_strict_check => $strict,
            find_submeta         => \&Sub::Meta::CreatorFunction::find_submeta,
        );
    }
}


1;
__END__