File Coverage

blib/lib/Sub/Meta/Library.pm

Criterion	Covered	Total	%
statement	54	54	100.0
branch	8	8	100.0
condition			n/a
subroutine	14	14	100.0
pod	7	7	100.0
total	83	83	100.0

package Sub::Meta::Library;
use 5.010;
use strict;
use warnings;

our $VERSION = "0.14";

use Scalar::Util ();
use Sub::Identify;
use Types::Standard qw(InstanceOf Str Ref);
use Type::Params qw(compile Invocant);

our %INFO;
our %INDEX;

my $SubMeta  = InstanceOf['Sub::Meta'];
my $Callable = Ref['CODE'];

sub register {
    state $check = compile(Invocant, $Callable, $SubMeta);
    my ($class, $sub, $meta) = $check->(@_);

    my $id = Scalar::Util::refaddr $sub;
    my ($stash, $subname) = Sub::Identify::get_code_info($sub);
    $INDEX{$stash}{$subname} = $id;
    $INFO{$id} = $meta;
    return;
}

sub register_list {
    my ($class, @list) = @_;

    for (@list) {
        $class->register(@$_)
    }
    return;
}

sub get {
    my ($class, $sub) = @_;
    return unless $Callable->check($sub);

    my $id = Scalar::Util::refaddr $sub;
    return $INFO{$id}
}

sub get_by_stash_subname {
    my ($class, $stash, $subname) = @_;

    my $id = $INDEX{$stash}{$subname};
    return $INFO{$id} if $id;
    return;
}

sub get_all_subnames_by_stash {
    my ($class, $stash) = @_;

    my $data = $INDEX{$stash};
    return [ sort keys %$data ] if $data;
    return [ ]
}

sub get_all_submeta_by_stash {
    my ($class, $stash) = @_;

    my $data = $INDEX{$stash};
    return [ map { $INFO{$data->{$_}} } sort keys %$data ] if $data;
    return [ ]
}

sub remove {
    state $check = compile(Invocant, $Callable);
    my ($class, $sub) = $check->(@_);

    my $id = Scalar::Util::refaddr $sub;
    my ($stash, $subname) = Sub::Identify::get_code_info($sub);
    delete $INDEX{$stash}{$subname};
    return delete $INFO{$id}
}

1;
__END__