File Coverage

blib/lib/String/TtyLength.pm

Criterion	Covered	Total	%
statement	26	26	100.0
branch			n/a
condition			n/a
subroutine	9	9	100.0
pod	2	2	100.0
total	37	37	100.0

package String::TtyLength;
$String::TtyLength::VERSION = '0.02';
use 5.006;
use strict;
use warnings;
use parent 'Exporter';
use Unicode::EastAsianWidth 12.0;

our @EXPORT_OK = qw/ tty_length tty_width /;

my $cursor_position     = qr/\e\[[0-9]+;[0-9]+[Hf]/;
my $cursor_movement     = qr/\e\[[0-9]+[ABCD]/;
my $save_restore_cursor = qr/\e\[[su]/;
my $clear_screen        = qr/\e\[2J/;
my $erase_line          = qr/\e\[K/;
my $graphics_mode       = qr/\e\[[0-9]+(;[0-9]+)*m/;
my $ansi_code           = qr/
                            (
                              $cursor_position
                            | $cursor_movement
                            | $save_restore_cursor
                            | $clear_screen
                            | $erase_line
                            | $graphics_mode
                            )
                            /x;



sub tty_length
{
    my $string = shift;
    return length(_remove_ansi_codes($string));
}

sub tty_width
{
    my $string = _remove_ansi_codes(shift);
    my $width  = length($string);

    $width++ while $string =~ /\p{InFullwidth}/msg;

    return $width;
}

# might make this an exportable function
# as well, but not sure what the right name is :-)
sub _remove_ansi_codes
{
    my $string = shift;
    $string =~ s/$ansi_code//mosg;
    return $string;
}

1;

__END__