File Coverage

blib/lib/String/Query/To/Regexp.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch	20	22	90.9
condition	2	2	100.0
subroutine	5	5	100.0
pod	1	1	100.0
total	62	64	96.8

package String::Query::To::Regexp;

use 5.010001;
use strict;
use warnings;

use Exporter 'import';
our @EXPORT_OK = qw(query2re);

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2022-11-02'; # DATE
our $DIST = 'String-Query-To-Regexp'; # DIST
our $VERSION = '0.003'; # VERSION

sub query2re {
    my $opts = ref($_[0]) eq 'HASH' ? {%{shift()}} : {};
    my $bool   = delete $opts->{bool} // 'and';
    my $ci     = delete $opts->{ci};
    my $word   = delete $opts->{word};
    my $opt_re = delete $opts->{re};
    die "query2re(): Unknown option(s): ".
        join(", ", sort keys %$opts) if keys %$opts;

    return qr// unless @_;
    my @re_parts;
    for my $query0 (@_) {
        my ($neg, $query) = $query0 =~ /\A(-?)(.*)/;

        if ($opt_re) {
            if (ref $query0 eq 'Regexp') {
                $query = $query0;
            } else {
                require Regexp::From::String;
                $query = Regexp::From::String::str_maybe_to_re($query);
                $query = quotemeta($query) unless ref $query eq 'Regexp';
            }
        } else {
            $query = quotemeta $query;
        }

        if ($word) {
            push @re_parts, $neg ? "(?!.*\\b$query\\b)" : "(?=.*\\b$query\\b)";
        } else {
            push @re_parts, $neg ? "(?!.*$query)" : "(?=.*$query)";
        }
    }
    my $re = $bool eq 'or' ? "(?:".join("|", @re_parts).")" : join("", @re_parts);
    return $ci ? qr/\A$re.*\z/is : qr/\A$re.*\z/s;
}

1;
# ABSTRACT: Convert query to regular expression

__END__