File Coverage

blib/lib/String/Pad.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	16	16	100.0
condition	7	8	87.5
subroutine	7	7	100.0
pod	1	1	100.0
total	71	72	98.6

package String::Pad;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2021-08-01'; # DATE
our $DIST = 'String-Pad'; # DIST
our $VERSION = '0.021'; # VERSION

use 5.010001;
use strict;
use warnings;

use Exporter;
our @ISA = qw(Exporter);
our @EXPORT_OK = qw(
                       pad
               );

sub pad {
    my ($text0, $width, $which, $padchar, $is_trunc) = @_;
    if ($which) {
        $which = substr($which, 0, 1);
    } else {
        $which = "r";
    }
    $padchar //= " ";

    my $texts = ref $text0 eq 'ARRAY' ? [@$text0] : [$text0];

    if (!defined($width) || $width < 0) {
        my $longest = 0;
        for (@$texts) {
            my $len = length($_);
            $longest = $len if $longest < $len;
        }
        $width = $longest;
    }

    for my $text (@$texts) {
        my $w = length($text);
        if ($is_trunc && $w > $width) {
            $text = substr($text, 0, $width, 1);
            $w = $width;
        } else {
            if ($which eq 'l') {
                no warnings; # negative repeat count
                $text = ($padchar x ($width-$w)) . $text;
            } elsif ($which eq 'c') {
                my $n = int(($width-$w)/2);
                $text = ($padchar x $n) . $text . ($padchar x ($width-$w-$n));
            } else {
                no warnings; # negative repeat count
                $text .= ($padchar x ($width-$w));
            }
        }
    } # for $text

    ref $text0 eq 'ARRAY' ? $texts : $texts->[0];
}

1;
# ABSTRACT: String padding routines

__END__