File Coverage

blib/lib/String/Elide/Tiny.pm

Criterion	Covered	Total	%
statement	27	28	96.4
branch	19	22	86.3
condition	4	4	100.0
subroutine	2	2	100.0
pod	1	1	100.0
total	53	57	92.9

## no critic: TestingAndDebugging::RequireUseStrict
package String::Elide::Tiny;

# be tiny
#IFUNBUILT
# use strict;
# use warnings;
#END IFUNBUILT

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2023-08-08'; # DATE
our $DIST = 'String-Elide-Tiny'; # DIST
our $VERSION = '0.003'; # VERSION

sub import {
    my $pkg = shift;
    my $caller = caller;
#IFUNBUILT
# no strict 'refs';
#END IFUNBUILT
    for my $sym (@_) {
        if ($sym eq 'elide') { *{"$caller\::$sym"} = \&{$sym} }
        else { die "$sym is not exported!" }
    }
}

sub elide {
    my ($str, $max_len, $opts) = @_;

    die "Please specify str" unless defined $str;
    die "Please specify max_len" unless defined $max_len;

    return "" if $max_len <= 0;

    $opts ||= {};

    my $str_len = length $str;
    return $str if $str_len <= $max_len;

    my $marker = defined $opts->{marker} ? $opts->{marker} : "...";
    my $marker_len = length $marker;
    return substr($marker, 0, $max_len) if $max_len < $marker_len;

    my $truncate = $opts->{truncate} || 'right';
    if ($truncate eq 'left') {
        return $marker . substr($str, $str_len - $max_len + $marker_len);
    } elsif ($truncate eq 'middle') {
        my $left  = substr($str, 0,
                           ($max_len - $marker_len)/2);
        my $right = substr($str,
                           $str_len - ($max_len - $marker_len - length($left)));
        return $left . $marker . $right;
    } elsif ($truncate eq 'ends') {
        if ($max_len <= 2 * $marker_len) {
            return substr($marker . $marker, 0, $max_len);
        }
        return $marker . substr($str, ($str_len - $max_len)/2 + $marker_len,
                                $max_len - 2*$marker_len) . $marker;
    } else { # right
        return substr($str, 0, $max_len - $marker_len) . $marker;
    }
}

1;
# ABSTRACT: A very simple text truncating function, elide()

__END__