File Coverage

blib/lib/Statistics/Diversity/Shannon.pm

Criterion	Covered	Total	%
statement	36	36	100.0
branch	6	8	75.0
condition			n/a
subroutine	9	9	100.0
pod			n/a
total	51	53	96.2

package Statistics::Diversity::Shannon;
our $AUTHORITY = 'cpan:GENE';

# ABSTRACT: Compute the Shannon diversity

use Moo;
use strictures 2;
use namespace::clean;

use List::Util qw(sum0);

our $VERSION = '0.01';


has data => (
    is  => 'ro',
    isa => sub { die 'Not an array reference' unless ref($_[0]) eq 'ARRAY' },
);

has freq => (
    is      => 'ro',
    isa     => sub { die 'Not an array reference' unless ref($_[0]) eq 'ARRAY' },
    builder => 1,
    lazy    => 1,
);

has N => (
    is      => 'ro',
    builder => 1,
    lazy    => 1,
);

has sum => (
    is      => 'ro',
    builder => 1,
    lazy    => 1,
);

has index => (
    is      => 'ro',
    builder => 1,
    lazy    => 1,
);

has evenness => (
    is      => 'ro',
    builder => 1,
    lazy    => 1,
);


sub _build_N {
    my $self = shift;
    my $n = $self->data ? scalar @{ $self->data } : $self->freq ? scalar @{ $self->freq } : 0;
    return $n;
}

sub _build_sum {
    my $self = shift;
    my $sum = $self->data ? sum0 @{ $self->data } : $self->freq ? sum0 @{ $self->freq } : 0;
    return $sum;
}

sub _build_freq {
    my $self = shift;

    my @freq;

    for my $datum ( @{ $self->data } ) {
        push @freq, $datum / $self->sum;
    }

    return \@freq;
}


sub _build_index {
    my $self = shift;

    my @index;

    for my $datum ( @{ $self->freq } ) {
        push @index, $datum * log($datum);
    }

    return -1 * sum0 @index;
}


sub _build_evenness {
    my $self = shift;
    return $self->index / log( $self->N );
}

1;

__END__