File Coverage

blib/lib/Starch/Plugin/Sereal.pm

Criterion	Covered	Total	%
statement	29	29	100.0
branch	2	2	100.0
condition			n/a
subroutine	11	11	100.0
pod	2	2	100.0
total	44	44	100.0

package Starch::Plugin::Sereal;

$Starch::Plugin::Sereal::VERSION = '0.03';

=head1 NAME

Starch::Plugin::Sereal - Use Sereal for cloning and diffing Starch data structures.

=head1 SYNOPSIS

    my $starch = Starch->new(
        plugins => ['::Sereal'],
    );

=head1 DESCRIPTION

By default L and L
use L to do the heavy lifting.  This module replaces those two methods
with ones that use L which can be leaps and bounds faster than Storable.

In this author's testing C will be about 3x faster with Sereal and
C will be about 1.5x faster with Sereal.

=cut

use Sereal::Encoder;
use Sereal::Decoder;
use Types::Standard -types;

use Moo::Role;
use strictures 2;
use namespace::clean;

with qw(
    Starch::Plugin::ForManager
);

=head1 MANAGER ATTRIBUTES

These attributes are added to the L class.

=head2 sereal_encoder

An instance of L.

=cut

has sereal_encoder => (
    is  => 'lazy',
    isa => InstanceOf[ 'Sereal::Encoder' ],
);
sub _build_sereal_encoder {
    return Sereal::Encoder->new();
}

=head2 sereal_decoder

An instance of L.

=cut

has sereal_decoder => (
    is  => 'lazy',
    isa => InstanceOf[ 'Sereal::Decoder' ],
);
sub _build_sereal_decoder {
    return Sereal::Decoder->new();
}

=head2 canonical_sereal_encoder

An instance of L with the C option set.

=cut

has canonical_sereal_encoder => (
    is  => 'lazy',
    isa => InstanceOf[ 'Sereal::Encoder' ],
);
sub _build_canonical_sereal_encoder {
    return Sereal::Encoder->new({ canonical => 1 });
}

=head1 MODIFIED MANAGER METHODS

These methods are added to the L class.

=head2 clone_data

Modified to use L and L to clone
a data structure.

=cut

sub clone_data {
    my ($self, $data) = @_;

    return $self->sereal_decoder->decode(
        $self->sereal_encoder->encode( $data ),
    );
}

=head2 is_data_diff

Modified to use L to encode the two data
structures.

=cut

sub is_data_diff {
    my ($self, $old, $new) = @_;

    my $encoder = $self->canonical_sereal_encoder();

    $old = $encoder->encode( $old );
    $new = $encoder->encode( $new );

    return 0 if $new eq $old;
    return 1;
}

1;
__END__