File Coverage

blib/lib/Spreadsheet/WriteExcel/Styler.pm

Criterion	Covered	Total	%
statement	43	50	86.0
branch	11	16	68.7
condition	4	6	66.6
subroutine	8	11	72.7
pod	6	6	100.0
total	72	89	80.9

package Spreadsheet::WriteExcel::Styler;
use warnings;
use strict;
use Carp;

our $VERSION = '1.02';

# shorthand notation: $styler->(..) instead of $styler->format(..)
use overload
  '&{}' => sub {my $self = shift; return sub {$self->format(@_)}};


sub new {
  my $class    = shift;
  my $workbook = shift;

  ref $workbook && $workbook->can('add_format')
    or croak "improper 'workbook' arg (has no 'add_format' method)";

  my $self = { workbook => $workbook, # ref to workbook
               style    => {},        # hash of styles and features
               format   => {},        # cache of created formats
             };
  bless $self, $class;
}

sub add_styles {
  my $self = shift;

  while (my ($style_name, $features) = splice(@_, 0, 2)) {
    carp "overriding style $style_name" if $self->{style}{$style_name};
    croak "features for style $style_name should be expressed as a hashref"
                                        if ref $features ne 'HASH';
    $self->{style}{$style_name} = $features;
  }
}


sub format {
  my $self = shift;

  # get styles from args (can be array, single arrayref or single hashref)
  my @styles;
  my $first_arg = shift;
  my $ref       = ref $first_arg;
  if ($ref) {
    not @_ or croak "too many args to format() when first arg is a ref";
    @styles = $ref eq 'ARRAY' ? @$first_arg
            : $ref eq 'HASH'  ? (grep {$first_arg->{$_}} keys %$first_arg)
            : croak "unexpected arg to format() ($ref)";
  }
  else {
    @styles = ($first_arg, @_);
  }

  # retrieve format for that combination of styles ... or create a new one
  my $format_name = join $;, sort @styles;
  $self->{format}{$format_name} ||= do {
    my @unknown = grep {!$self->{style}{$_}} @styles;
    !@unknown
      or croak "unknown style : " . join ", ", @unknown;
    $self->{workbook}->add_format(map {%{$self->{style}{$_}}} @styles);
  };
  return $self->{format}{$format_name};
}

sub workbook {
  my $self = shift;
  return $self->{workbook};
}

sub styles {
  my $self = shift;
  return keys %{$self->{style}};
}

sub style {
  my ($self, $style_name) = @_;
  return $self->{style}{style_name};
}

1; # End of Spreadsheet::WriteExcel::Styler

__END__