File Coverage

blib/lib/Sort/strverscmp.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	14	16	87.5
condition	9	12	75.0
subroutine	10	10	100.0
pod	2	3	66.6
total	75	81	92.5

package Sort::strverscmp;

require Sort::strverscmp::StringIterator;

use Exporter 'import';
use 5.010;

use strict;
use warnings;

our $VERSION = "0.014";
our @EXPORT = qw(strverscmp);
our @EXPORT_OK = qw(strverssort versionsort);

# strnum_cmp from bam_sort.c
sub strverscmp($$) {
    my $ai = Sort::strverscmp::StringIterator->new($_[0]);
    my $bi = Sort::strverscmp::StringIterator->new($_[1]);

    do {
        if (_isdigit($ai->head) && _isdigit($bi->head)) {
            my $an = (($ai->head . $ai->tail) =~ /^(\d*)/)[0];
            my $bn = (($bi->head . $bi->tail) =~ /^(\d*)/)[0];
            if ($an =~ /^0\d/ || $bn =~ /^0\d/) {
                return _fcmp($an, $bn);
            } else {
                if ($an <=> $bn) {
                    return ($an <=> $bn);
                }
            }
        } else {
            if ($ai->head cmp $bi->head) {
                return ($ai->head cmp $bi->head);
            }
        }
        $ai->advance();
        $bi->advance();
    } while (defined($ai->head) && defined($bi->head));

    return $ai->head ? 1 : $bi->head ? -1 : 0;
}

sub versionsort { &strverssort }
sub strverssort {
    return sort { strverscmp($a, $b) } @_;
}

sub _isdigit {
    my $c = shift;
    return (defined($c) && $c =~ /^\d+$/);
}

sub _fcmp {
    my ($l, $r) = @_;

    my ($lz, $ln, $rz, $rn);
    ($lz, $ln) = _decompose_fractional($l);
    ($rz, $rn) = _decompose_fractional($r);

    if (length($lz) == length($rz)) {
        return $ln <=> $rn;
    } else {
        return (length($lz) > length($rz) ? -1 : 1);
    }
}

sub _decompose_fractional {
    my ($zeroes, $number) = shift =~ /^(0*)(\d+)$/;
    return ($zeroes, $number);
}

1;
__END__