File Coverage

blib/lib/SmokeRunner/Multi/SafeRun.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	4	6	66.6
condition			n/a
subroutine	10	10	100.0
pod	1	1	100.0
total	50	52	96.1

package SmokeRunner::Multi::SafeRun;
BEGIN {
  $SmokeRunner::Multi::SafeRun::AUTHORITY = 'cpan:YANICK';
}
{
  $SmokeRunner::Multi::SafeRun::VERSION = '0.19';
}
#ABSTRACT: Run an external command safely in taint mode

use strict;
use warnings;

use base 'Exporter';

our @EXPORT_OK = 'safe_run';

use Cwd qw( abs_path );
use File::Spec;
use File::Which qw( which );
use SmokeRunner::Multi::Validate
    qw( validate SCALAR_TYPE ARRAYREF_TYPE SCALARREF_TYPE );
use IPC::Run3 qw( run3 );


{
    my $spec = { command       => SCALAR_TYPE,
                 args          => ARRAYREF_TYPE( default => [] ),
                 stdout_buffer => SCALARREF_TYPE,
                 stderr_buffer => SCALARREF_TYPE,
               };

    sub safe_run
    {
        my %p = validate( @_, $spec );

        my $cmd;
        if ( File::Spec->file_name_is_absolute( $p{command} ) )
        {
            $cmd = $p{command};

            die "$cmd is not executable"
                unless -x $cmd;
        }
        else
        {
            $cmd = which( $p{command} )
                or die "Cannot find $p{command} in path";

            $cmd = abs_path($cmd);
        }

        # This is a simple way to make the path taint-safe.
        local $ENV{PATH} = '';
        run3( [ $cmd, @{ $p{args} } ],
              undef,
              $p{stdout_buffer}, $p{stderr_buffer}
            );
    }
}


1;

__END__