File Coverage

lib/Sisimai/Reason/VirusDetected.pm

Criterion	Covered	Total	%
statement	23	23	100.0
branch	5	8	62.5
condition	3	4	75.0
subroutine	7	7	100.0
pod	2	4	50.0
total	40	46	86.9

package Sisimai::Reason::VirusDetected;
use feature ':5.10';
use strict;
use warnings;

sub text  { 'virusdetected' }
sub description { 'Email rejected due to a virus scanner on a destination host' }
sub match {
    # Try to match that the given text and regular expressions
    # @param    [String] argv1  String to be matched with regular expressions
    # @return   [Integer]       0: Did not match
    #                           1: Matched
    # @since v4.22.0
    my $class = shift;
    my $argv1 = shift // return undef;

    state $index = [
        'it has a potentially executable attachment',
        'the message was rejected because it contains prohibited virus or spam content',
        'this form of attachment has been used by recent viruses or other malware',
        'virus detected',
        'your message was infected with a virus',
    ];
    return 1 if grep { rindex($argv1, $_) > -1 } @$index;
    return 0;
}

sub true {
    # The bounce reason is security error or not
    # @param    [Sisimai::Data] argvs   Object to be detected the reason
    # @return   [Integer]               1: virus detected
    #                                   0: virus was not detected
    # @since v4.22.0
    # @see http://www.ietf.org/rfc/rfc2822.txt
    my $class = shift;
    my $argvs = shift // return undef;

    # The value of "reason" isn't "virusdetected" when the value of "smtpcommand" is an SMTP com-
    # mand to be sent before the SMTP DATA command because all the MTAs read the headers and the
    # entire message body after the DATA command.
    return 1 if $argvs->{'reason'} eq 'virusdetected';
    return 0 if $argvs->{'smtpcommand'} =~ /\A(?:CONN|EHLO|HELO|MAIL|RCPT)\z/;
    return 1 if __PACKAGE__->match(lc $argvs->{'diagnosticcode'});
    return 0;
}

1;
__END__