File Coverage

lib/Sisimai/Mail/Mbox.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	13	20	65.0
condition	5	7	71.4
subroutine	8	8	100.0
pod	2	2	100.0
total	76	85	89.4

package Sisimai::Mail::Mbox;
use feature ':5.10';
use strict;
use warnings;
use File::Basename qw(basename dirname);
use IO::File;
use Class::Accessor::Lite (
    'new' => 0,
    'ro'  => [
        'dir',      # [String]  Directory name of the mbox
        'file',     # [String]  File name of the mbox
        'path',     # [String]  Path to mbox
        'size',     # [Integer] File size of the mbox
    ],
    'rw'  => [
        'offset',   # [Integer]  Offset position for seeking
        'handle',   # [IO::File] File handle
    ]
);

sub new {
    # Constructor of Sisimai::Mail::Mbox
    # @param    [String] argv1          Path to mbox
    # @return   [Sisimai::Mail::Mbox]   Object
    #           [Undef]                 is not a file or does not exist
    my $class = shift;
    my $argv1 = shift // return undef;
    my $param = { 'offset' => 0 };
    return undef unless -f $argv1;

    $param->{'dir'}    = File::Basename::dirname $argv1;
    $param->{'path'}   = $argv1;
    $param->{'size'}   = -s $argv1;
    $param->{'file'}   = File::Basename::basename $argv1;
    $param->{'handle'} = ref $argv1 ? $argv1 : IO::File->new($argv1, 'r');
    binmode $param->{'handle'};

    return bless($param, __PACKAGE__);
}

sub read {
    # Mbox reader, works as a iterator.
    # @return   [String] Contents of mbox
    my $self = shift;

    my $seekoffset = $self->{'offset'} // 0;
    my $filehandle = $self->{'handle'};
    my $readbuffer = '';

    return undef unless defined $self->{'path'};
    unless( ref $self->{'path'} ) {
        # "path" is not IO::File object
        return undef unless -f $self->{'path'};
        return undef unless -T $self->{'path'};
    }
    return undef unless $self->{'offset'} < $self->{'size'};

    eval {
        $seekoffset = 0 if $seekoffset < 0;
        seek($filehandle, $seekoffset, 0);

        while( my $r = <$filehandle> ) {
            # Read the UNIX mbox file from 'From ' to the next 'From '
            last if( $readbuffer && substr($r, 0, 5) eq 'From ' );
            $readbuffer .= $r;
        }
        $seekoffset += length $readbuffer;
        $self->{'offset'} = $seekoffset;
        $filehandle->close unless $seekoffset < $self->{'size'};
    };
    return $readbuffer;
}

1;
__END__