File Coverage

lib/Settlers/Map/Intersection.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	10	14	71.4
condition	10	21	47.6
subroutine	10	10	100.0
pod	0	4	0.0
total	74	93	79.5

package Settlers::Map::Intersection;
$Settlers::Map::Intersection::VERSION = '0.07';
use strict;
use warnings;

use overload
  '""' => 'uuid',
  fallback => 1;

sub new
{
  my ($class, $tiles) = @_;

  die 'Intersection->new() requires an arrayref of 3 tiles'
    unless $tiles && ref $tiles eq 'ARRAY' && @$tiles == 3;

  # check tiles are joined
  for my $t1 (@$tiles)
  {
    for my $t2 (@$tiles)
    {
      die 'Invalid intersection - all 3 tiles must be next to each other'
        unless $t1 eq $t2 || $t1->hex_distance($t2) == 1;
    }
  }

  bless {
    location => $tiles,
    uuid     => join('|', map {$_->id} sort {$a->id cmp $b->id}  @$tiles),
  }, $class;
}

sub uuid { $_[0]->{uuid} }

sub is_colliding
{
  my ($self, $location) = @_;

  die 'is_colliding requires an Intersection or Path object as an argument'
    unless $location && ($location->isa('Settlers::Map::Intersection')
                         || $location->isa('Settlers::Map::Path'));
  return $location->isa('Settlers::Map::Path')
          ? $location->is_colliding($self)
          : $self eq $location;
}

sub is_adjacent
{
  my ($self, $location) = @_;

  die 'is_adjacent requires an Intersection or tile object as an argument'
    unless $location
      && ( $location->isa('Settlers::Map::Intersection')
           || $location->isa('Settlers::Map::Tile'));

  my ($matching_tiles, $tiles_to_match) = (0);
  if ($location->isa('Settlers::Map::Intersection'))
  {
    $tiles_to_match = 2;

    # intersections are adjacent if they share 2 coordinates with the intersection
    for my $hex (@{$self->{location}})
    {
      $matching_tiles += grep($hex eq $_, @{$location->{location}});
    }
  }
  else
  {
    $tiles_to_match = 1;
    # tiles are adjacent if they share 1 coordinate with the intersection
    for my $tile (@{$self->{location}})
    {
      $matching_tiles += $tile eq $location ? 1 : 0;
    }
  }
  return $matching_tiles == $tiles_to_match;
}

1;

__END__