File Coverage

blib/lib/Set/Similarity/CosinePP.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	2	2	100.0
condition			n/a
subroutine	10	10	100.0
pod	1	1	100.0
total	54	54	100.0

package Set::Similarity::CosinePP;

use strict;
use warnings;

use parent 'Set::Similarity';

our $VERSION = '0.016';

sub from_sets {
  my ($self, $set1, $set2) = @_;
  my $cosine = $self->_cosine(
	$self->_normalize($self->_make_vector( $set1 )),
	$self->_normalize($self->_make_vector( $set2 ))
  );
  return $cosine;
}

sub _make_vector {
  my ( $self, $tokens ) = @_;
  my %elements;
  do { $_++ } for @elements{@$tokens};
  return \%elements;
}

# Assumes both incoming vectors are normalized
sub _cosine { shift->_dot( @_ ) }

sub _norm {
  my $self = shift;
  my $vector = shift;
  my $sum = 0;
  for my $key (keys %$vector) {
    $sum += $vector->{$key} ** 2;
  }
  return sqrt $sum;
}

sub _normalize {
  my $self = shift;
  my $vector = shift;

  return $self->_div(
    $vector,
    $self->_norm($vector)
  );
}

sub _dot {
  my $self = shift;
  my $vector1 = shift;
  my $vector2 = shift;

  my $dotprod = 0;

  for my $key (keys %$vector1) {
    $dotprod += $vector1->{$key} * $vector2->{$key} if ($vector2->{$key});
  }
  return $dotprod;
}


# divides each vector entry by a given divisor
sub _div {
  my $self = shift;
  my $vector = shift;
  my $divisor = shift;

  my $vector2 =  {};
  for my $key (keys %$vector) {
    $vector2->{$key} = $vector->{$key} / $divisor;
  }
  return $vector2;
}


1;


__END__