File Coverage

blib/lib/Selenium/Screenshot/CanPad.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	6	12	50.0
condition	7	12	58.3
subroutine	8	8	100.0
pod	2	2	100.0
total	56	67	83.5

package Selenium::Screenshot::CanPad;
$Selenium::Screenshot::CanPad::VERSION = '0.08';
use Scalar::Util qw/blessed/;
use Carp qw/croak/;
# ABSTRACT: Provides subs for coercing two images to the exact width and height
use Moo::Role;



sub coerce_image_size {
    my ($self, $image1, $image2) = @_;

    foreach ( $image1, $image2 ) {
        croak 'Expected two Imager objects' unless blessed $_ && $_->isa('Imager');
    }

    my $coerce_dims = _get_largest_dimensions( $image1, $image2 );

    if ( _is_smaller( $image1, $coerce_dims ) ) {
        $image1 = _pad_image( $image1, $coerce_dims );
    }

    if ( _is_smaller( $image2, $coerce_dims ) ) {
        $image2 = _pad_image( $image2, $coerce_dims );
    }

    return ( $image1, $image2 );
}


sub cmp_image_dims {
    my ($self, $image1, $image2) = @_;

    foreach ( $image1, $image2 ) {
        croak 'Expected two Imager objects'
          unless blessed $_ && $_->isa('Imager');
    }

    return $image1->getheight == $image2->getheight &&
      $image1->getwidth == $image2->getwidth;
}

sub _get_largest_dimensions {
    my ($image1, $image2) = @_;

    my $max_width = $image1->getwidth >= $image2->getwidth
      ? $image1->getwidth
      : $image2->getwidth;

    my $max_height = $image1->getheight >= $image2->getheight
      ? $image1->getheight
      : $image2->getheight;

    my $dimensions = {
        width => $max_width,
        height => $max_height
    };

    return $dimensions
}

sub _is_smaller {
    my ($image, $dimensions) = @_;

    return $image->getwidth < $dimensions->{width} ||
      $image->getheight < $dimensions->{height};
}

sub _pad_image {
    my ($image, $dimensions) = @_;

    my $padded_image = Imager->new(
        xsize => $dimensions->{width},
        ysize => $dimensions->{height},
        channels => $image->getchannels
    );

    $padded_image->paste(
        left => 0,
        top => 0,
        img => $image
    );

    return $padded_image;
}

1;

__END__