File Coverage

blib/lib/Search/Elasticsearch/Cxn/AEHTTP.pm

Criterion	Covered	Total	%
statement	17	22	77.2
branch	1	8	12.5
condition			n/a
subroutine	6	7	85.7
pod	0	1	0.0
total	24	38	63.1

# Licensed to Elasticsearch B.V. under one or more contributor
# license agreements. See the NOTICE file distributed with
# this work for additional information regarding copyright
# ownership. Elasticsearch B.V. licenses this file to you under
# the Apache License, Version 2.0 (the "License"); you may
# not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#   http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing,
# software distributed under the License is distributed on an
# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
# KIND, either express or implied.  See the License for the
# specific language governing permissions and limitations
# under the License.

package Search::Elasticsearch::Cxn::AEHTTP;
$Search::Elasticsearch::Cxn::AEHTTP::VERSION = '7.715';
use AnyEvent::HTTP qw(http_request);
use Promises qw(deferred);
use Try::Tiny;
use Moo;

with 'Search::Elasticsearch::Role::Cxn::Async';
with 'Search::Elasticsearch::Role::Cxn',
    'Search::Elasticsearch::Role::Is_Async';

has '_tls_ctx' => ( is => 'lazy' );

use namespace::clean;

#===================================
sub _build__tls_ctx {
#===================================
    my $self = shift;
    return 'low' unless $self->has_ssl_options;
    require AnyEvent::TLS;
    return AnyEvent::TLS->new( %{ $self->ssl_options } );
}

#===================================
sub perform_request {
#===================================
    my ( $self, $params ) = @_;
    my $uri     = $self->build_uri($params);
    my $method  = $params->{method};
    my %headers = ( %{ $self->default_headers } );
    my $data    = $params->{data};
    if ( defined $data ) {
        $headers{'Content-Type'}     = $params->{mime_type};
        $headers{'Content-Encoding'} = $params->{encoding}
            if $params->{encoding};
    }

    my $deferred = deferred;

    http_request(
        $method => $uri,
        headers => \%headers,
        timeout => $params->{timeout} || $self->request_timeout,
        body => $data,
        persistent => 0,
        session    => $self->_pid,
        ( %{ $self->handle_args } ),
        ( $self->is_https ? ( tls_ctx => $self->_tls_ctx ) : () ),
        sub {
            my ( $body, $headers ) = @_;
            try {
                my ( $code, $response ) = $self->process_response(
                    $params,                      # request
                    delete $headers->{Status},    # code
                    delete $headers->{Reason},    # msg
                    $body,                        # body
                    $headers                      # headers
                );
                $deferred->resolve( $code, $response );
            }
            catch {
                $deferred->reject($_);
            }

        }
    );
    $deferred->promise;
}

#===================================
sub error_from_text {
#===================================
    local $_ = $_[2];
    return
          /[Tt]imed out/              ? 'Timeout'
        : /certificate verify failed/ ? 'SSL'
        : /Invalid argument/          ? 'Cxn'
        :                               'Request';
}

1;

# ABSTRACT: An async Cxn implementation which uses AnyEvent::HTTP

__END__