File Coverage

blib/lib/Scope/Container.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	11	12	91.6
condition	3	3	100.0
subroutine	9	9	100.0
pod	3	3	100.0
total	65	66	98.4

package Scope::Container;

use strict;
use warnings;
use 5.008_001;
use Carp qw//;
use base qw/Exporter/;

our $VERSION = '0.04';
our @EXPORT = qw/start_scope_container scope_container in_scope_container/;

my $CONTEXT;
my $C = 0;

sub start_scope_container {
    my %args = @_;
    my $old;
    if ( defined $CONTEXT and !$args{-clear} ) {
        $old = $CONTEXT;
        $CONTEXT = { map { $_ => $old->{$_} } keys %$old };
    }
    else {
        $CONTEXT = {};
    }

    return bless { c => $C++, old => $old }, __PACKAGE__;
}

sub DESTROY {
    my($self) = @_;
    if ( $self->{c} != --$C ) {
        Carp::carp("nested scope_container found, remove all data");
        undef $CONTEXT;
    }
    else {
        $CONTEXT = $self->{old};
    }
    return;
}

sub in_scope_container {
    defined $CONTEXT;
}

sub scope_container {
    my $key = shift;
    die "undefined key" if ! defined $key;
    if ( ! defined $CONTEXT ) {
        Carp::carp("scope_container is not initilized");
        return;
    }
    if ( @_ ) {
        return $CONTEXT->{$key} = shift;
    }
    return if ! exists $CONTEXT->{$key};
    $CONTEXT->{$key};
}

1;
__END__